هل ممكن جعل برنامج الجافا ينادي عن طريق ال فيجوال بيسك؟؟؟

أعتقد أن ذلك سهل:

لتشغيل برنامج جافا:

c://[java home]/bin/java.exe c://[Path to Program}/ProgramName

بسم الله الرحمن الرحيم

اخي الفاضل

هل الكود الذي كتبته يجب ان يكتب في الفيجوال بيسك ام ماذا؟؟

ا

علسكم السلام,

كما أشار أخي و معلمي الأستاذ أبو مازن:

في ال vb هناك دوال لتشغيل البرامج الخارجيه, استخدم هذه الدوال و اكتب بها السطر الذي تفضل الأخ أبو مازن

alslam 3alaykom

Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long

Private Sub Command1_Click()
'to compile file
Call RunJavaFile("C:\Documents and Settings\Alaa\Desktop\New Folder\asd\Alaa.java")
'to run class
Call RunJavaFile("C:\Documents and Settings\Alaa\Desktop\New Folder\asd\Alaa.class")
End Sub

Function RunJavaFile(ByVal FileName As String)
Dim JavaExeFileName As String
BinDir = "C:\Program Files\Java\jdk1.5.0_04\bin\"
Dim JavaFileName As String
JavaFileName = GetFileName(FileName)
Select Case LCase(GetFileExtintion(FileName))
   Case "class"  ' java file name  to run the class
	  JavaExeFileName = BinDir + "java"
	  'Remove .class extintion from the file name
	  JavaFileName = IIf(InStr(JavaFileName, ".") > 0, Left(JavaFileName, InStr(JavaFileName, ".") - 1), JavaFileName)

   Case "java"   ' java compiler filename
	  JavaExeFileName = BinDir + "javac"

   Case "html", "htm" 'appletviewer path
	  JavaExeFileName = BinDir + "AppletViewer"

   Case Else
	  'Add what ever like jar
	  MsgBox "unknown file type"
	  Exit Function
End Select
  Res = ShellExecute(0, vbNullString, JavaExeFileName, JavaFileName, GetFileDirectory(FileName), 1)
  If Res = 2 Then MsgBox "Error in Runing Program (" & JavaExeFileName & ")", vbCritical, "Error"

 ' if you want you can creat a batch file so you can use pause command
 ' like this
'  BStr = "echo off" + vbNewLine + _
'		"echo   Running File " + FileName + vbNewLine + _
'		"call " + JavaExeFileName + " " + JavaFileName + vbNewLine + _
'		"PAUSE"
' and save this text in a .bat file
' then call
' Res = ShellExecute(0, vbNullString, BatchFileName, "",  GetFileDirectory(FileName), 1)


End Function


Function GetFileExtintion(ByVal FileName As String)
	FileName = GetFileName(FileName)
	If InStr(FileName, ".") > 0 Then
		FileName = Mid(FileName, InStrRev(FileName, ".") + 1)
	End If
	GetFileExtintion = FileName
End Function


Function GetFileName(ByVal FileName As String)
	If InStr(FileName, "\") > 0 Then
		FileName = Mid(FileName, InStrRev(FileName, "\") + 1)
	End If
	GetFileName = FileName
End Function


Function GetFileDirectory(ByVal FileName As String)
	If InStr(FileName, "\") > 0 Then
		FileName = Left(FileName, InStrRev(FileName, "\"))
		GetFileDirectory = FileName
	End If
End Function

so you can put this code in the sub main

Sub Main()
	If Trim(Command) <> "" Then
	   Call RunJavaFile(Command)
	End If
	End
End Sub

and in the regestry editor you can add a new command to the .java and .class

the application path %1