كود يتعرف على ارقام الهاتف ويشغل برنامج

Mr_ZAD كتب:

يااخى الفاضل لقد تكرم الاخ g-johnny بموضع اكثر من اداه مع الامثلة الخاصة بيها

ومن ضمن الامثله التعرف على الارقام المضغوطة فماذا تنظر من الخبراء

مع ان رد الاخ g-johnny كافى ولايحتاج لإضافة الخبراء

اخي الفاضل على رسلك اين هذا الشرح الذي تقوله؟؟ بحثت بكامل الموضوع وما يحمل من وصلات ولم اجده فان كنت ترا شي لا اراه فدلني عليه مشكور وتذكر ان سؤالي هو كيف اعرف الرقم الذي تم الضغط عليه من جهت المتصل فان كنت تقصد شي اخر فلست بحاجه له وان كان قصدك ما طلبته انا فدلني عليه ولك الاجر والشكر الجزيل وان كان لا فاتمنى التاني قبل الرد وشكراً

السلام عليكم ورحمة الله وبركاته

اخى العزيز

لقد قام الاخ g-johnny بإضافة روابط لبعض الادوات التى لو قمت بتثبيتها

لوجدت لها امثله كثير توضح الكثير من إستخدامات تلك الادوات

هيا اى نعم ان الادوات غير مجانية وديمو بس يمكن الاستفادة منها

أداة التلى تولز

وعليكم السلام ورحمة الله وبركاته

حياك الله اخي الكريم ولكن ولا تزعل مني لم تقراء سؤالي جيداً ولو قراءته لما رديت بما سبق سؤالي الاصلي هو

zaid000 كتب:

اخي g-johnny جزاك الله خير

اتمنى التوضيح كيف يتعرف البرنامج على الرقم المضغوط عليه

وطريقة عرض المسج على المتصل

ولك جزيل الشكر

وهو واضح ولم اسئل غيره سؤال اي لم يكون هناك لبس حتى اقول انك اخي الكريم لم تنتبه كان سؤالي ليس عن الاداة فالاداة عملت عليها والحمد لله افهم بها الكثير ولكن كان سؤالي كما يتضح من الاقتباس اني اريد معرفة الرقم الذي قام المتصل بالضغط عليه فقط

لهذا اتمنى اخي الكريم ان يكون ردك بعد التمعن بسؤال الناس حتى لا تخرج عن الموضوع او يحصل اي امر آخر لهذا اتمنى منك الانتباه بالمرات القادمه

ولك تحياتي :)

--------- يبقى السؤال قائم كما بالاقتباس ولكم جزيل الشكر

<_<

افضلها الــ.. Modem tools لابد ان يكون لديك Voice Momem لتشغيل ملفات صوتيه للرد الآلي او ارسال ملف صوتي للاتصال .. كما انه تم طرح الموضوع في المنتدى وبشكل مفصل حتى النخاع .

اخي الفاضل هل اعطيتني الوصلة لهذا الموضوع ولك جزيل الشكر

بنتظار احد الاخوه الخبراء

هذا الكود والشرح سيأتي لاحقا لضيق الوقت لدي خلال هذه الفتره كما تعلمون كل عام وانتم بخير

مع ملاحظة انكم تحتاجون لاداوات المودم ModemTools

Option Explicit
'
' This Demo program allows the user to control all available functions of the modem manually.
'
' Manual Answer, Manual Dial, Manual Hangup, Auto-Hangup when remote disconnect is detected(depends on Modem).
' NOTE:- Will Auto-Hangup if Dial Tone, Busy Tone or Disconnect Tone is detected after the call is established.
'
' A wave file can be recorded from line to a file named "Record.wav"
' Record Gain can be Adjusted.
' Silence Detection will be Displayed during Recording.
' "Record.wav" can be copied to "Play.wav"
' "Play.wav" may be played to Line or the Sound Card.
' Play Volume can be adjusted.
'
' Caller ID will be Displayed on incoming calls, if available.
' Remote DTMF Tone Digits will be Displayed, if available.
'
' The Speaker Phone Mic and Speakers can be manually operated, if available.
' Speaker Phone Mic Gain and Speaker Volume can be adjusted, if available.
' The Local Phone Mic and Speaker(Earphone) can be manually operated, if available.
' The Local Phone Hookswitch state - On Hook or Off Hook, will be displayed,  if available.
'
' The Translated Telephone Number is Displayed.
'
' Call Progres is Displayed - Connected, Disconnected, The Phone Has Rung x Times.
'
Dim ModemWaveID As Long

Private Sub chkOwnIncoming_Click()
	'
	Dim OpenModemID As Long
	OpenModemID = ModemPhone1.ModemID
	If OpenModemID <> -1 Then ' if there is an open modem
		OpenModem (OpenModemID) ' re-open modem with new ownership
	End If
	'
End Sub

Private Sub chkOwnPhone_Click()
	'
	Dim OpenModemID As Long
	OpenModemID = ModemPhone1.ModemID
	If OpenModemID <> -1 Then ' if there is an open modem
		If (ModemCaps And CapSpeakerPhone) <> 0 Then ' if there is a phone device
			OpenModem (OpenModemID) ' re-open modem with new ownership
		End If
	End If
	'
End Sub

Private Sub cmdAnswer_Click()
	'
	ModemPhone1.Answer
	'
End Sub

Private Sub cmdDial_Click()
	' See comments in frmLocation for details about translation of telephone numbers
	'
	Dim Translate As Boolean
	Dim DisplayNumber As String
	If chkTranslateNumber.Value = 1 Then
		Translate = True
	Else
		Translate = False ' the number dialled will be a concatination of CountryCode, AreaCode and Number
	End If
	'
	' For Tapi to translate the number it must be presented seperately as CountryCode, AreaCode and Number
	DisplayNumber = ModemPhone1.MakeCall(txtCountryCode, txtAreaCode, txtNumber, Translate)
	lblDialling.Caption = "Dialling: " & DisplayNumber
	'
End Sub

Private Sub cmdHangUp_Click()
	'
	ModemPhone1.Hangup
	'
End Sub

Private Sub cmdLPMic_Click()
	'
	ModemPhone1.LocalPhone = Mic
	GetLocalPhoneStatus
	'
End Sub

Private Sub cmdLPMicSpeaker_Click()
	'
	ModemPhone1.LocalPhone = MicSpeaker
	GetLocalPhoneStatus
	'
End Sub

Private Sub cmdLPOff_Click()
	'
	ModemPhone1.LocalPhone = Off
	GetLocalPhoneStatus
	'
End Sub

Private Sub cmdLPSpeaker_Click()
	'
	ModemPhone1.LocalPhone = Speaker
	GetLocalPhoneStatus
	'
End Sub

Private Sub cmdSPMic_Click()
	'
	If ((cmdRecord.Enabled = False) Or (cmdPlay.Enabled = False)) Then
		If MsgBox("Turning the Speaker Phone On While Playing or Recording Causes Some Modems to Lock Up" & _
		vbCrLf & "and May Require a Re-Boot and Power Down of the Modem to Reset", vbOKCancel, "WARNING") = vbCancel Then Exit Sub
	End If
	'
	ModemPhone1.SpeakerPhone = Mic
	GetSpeakerStatus
	'
End Sub

Private Sub cmdSPMicSpeaker_Click()
	'
	If ((cmdRecord.Enabled = False) Or (cmdPlay.Enabled = False)) Then
		If MsgBox("Turning the Speaker Phone On While Playing or Recording Causes Some Modems to Lock Up" & _
		vbCrLf & "and May Require a Re-Boot and Power Down of the Modem to Reset", vbOKCancel, "WARNING") = vbCancel Then Exit Sub
	End If
	'
	ModemPhone1.SpeakerPhone = MicSpeaker
	GetSpeakerStatus
	'
End Sub

Private Sub cmdSPOff_Click()
	'
	ModemPhone1.SpeakerPhone = Off
	GetSpeakerStatus
	'
End Sub

Private Sub cmdSPSpeaker_Click()
	'
	If ((cmdRecord.Enabled = False) Or (cmdPlay.Enabled = False)) Then
		If MsgBox("Turning the Speaker Phone On While Playing or Recording Causes Some Modems to Lock Up" & _
		vbCrLf & "and May Require a Re-Boot and Power Down of the Modem to Reset", vbOKCancel, "WARNING") = vbCancel Then Exit Sub
	End If
	'
	ModemPhone1.SpeakerPhone = Speaker
	GetSpeakerStatus
	'
End Sub

Private Sub Form_Load()
	Me.Icon = LoadPicture(App.Path & "\WavePhone.ico")
	' Get the saved ModemID from the registry.
	Dim ModemIDFromRegistry As Long
	ModemIDFromRegistry = CLng(GetSetting(App.EXEName, "Modem", "ModemID", "-1"))
	'
	OpenModem ModemIDFromRegistry
	'
End Sub

Private Sub Form_Unload(Cancel As Integer)
	'
	SaveSetting App.EXEName, "Modem", "ModemID", CStr(ModemPhone1.ModemID)
	'
End Sub


Private Sub ModemPhone1_CallerID(Number As String, Name As String)
	'
	txtCallerID.SelText = Format(Now, "dddd, mmmm dd yyyy h:mm AM/PM") & vbCrLf
	txtCallerID.SelText = Name & vbCrLf
	txtCallerID.SelText = "Number:" & Number & vbCrLf & vbCrLf
	'
End Sub

Private Sub ModemPhone1_Connected(WaveID As Long)
	'
	lblLineState.Caption = "Connected"
	ModemWaveID = WaveID ' save the WaveID, if WaveID = -1 then no wave device available
	GetSpeakerStatus
	GetLocalPhoneStatus
	'
End Sub

Private Sub ModemPhone1_DigitReceived(Digit As String)
	'
	lblDigit.Caption = Digit
	'
End Sub

Private Sub ModemPhone1_Disconnected()
	'
	lblLineState.Caption = "Disconnected"
	GetSpeakerStatus
	GetLocalPhoneStatus
	'
End Sub

Private Sub ModemPhone1_Error(ErrNumber As Long, ErrDescription As String)
	'
	MsgBox "Error No " & ErrNumber & " " & ErrDescription
	'
	' Errors Can Be:-
	'  1 - Failed To Initialize Tapi
	'  2 - No Modems Installed
	'  3 - No Such Modem
	'  4 - Failed To Close Modem
	'  5 - Failed To Open Modem
	'  6 - Not a Voice Modem
	'  7 - Failed To Open Phone
	'  8 - Failed To Close Phone
	'  9 - Failed To Set Status Messages
	' 10 - Failed To De-Allocate Call
	' 11 - Failed To Get Country Code
	' 12 - Failed To Make Call
	' 13 - Modem In Use
	' 14 - Failed To Translate Number
	' 15 - HookSwitch Not Available
	' 16 - Failed To Set Local Phone State
	' 17 - Failed To Set Speaker Phone State
	' 18 - Failed To Get Speaker Phone Status
	' 19 - Failed To Get Local Phone Status
	' 20 - Failed To Set Mic Gain
	' 21 - Failed To Get Mic Gain
	' 22 - Failed To Set Speaker Volume
	' 23 - Failed To Get Speaker Volume
	' 24 - Failed To Set Location
	' 25 - Failed to Get CallerID Capabilities
End Sub

Private Sub ModemPhone1_HookSwich(OnHook As Boolean)
	'
	If OnHook Then
		lblHook.Caption = "On Hook"
	Else
		lblHook.Caption = "Off Hook"
	End If
	GetSpeakerStatus
	GetLocalPhoneStatus
	'
End Sub

Private Sub ModemPhone1_IncomingCall(RingNumber As Long)
	'
	lblLineState.Caption = "The Phone Has Rung " & RingNumber
	'
End Sub

Private Sub cmdCopy_Click()
	'
	FileCopy App.Path & "\Record.wav", App.Path & "\Play.wav"
	'
End Sub

Private Sub cmdPlay_Click()
	'
	If ((ModemCaps And CapSpeakerPhone) <> 0) Then
		If ModemPhone1.SpeakerPhone <> Off Then
			If MsgBox("Playing While The Speaker Phone is On Causes Some Modems to Lock Up" & _
			vbCrLf & "and May Require a Re-Boot and Power Down of the Modem to Reset", vbOKCancel, "WARNING") = vbCancel Then Exit Sub
		End If
	End If
	'
	ModemWave1.PlayFileName = App.Path & "\Play.wav"
	If optWave(0).Value Then
		ModemWave1.Play (0)
	Else
		ModemWave1.Play (ModemWaveID)
	End If
	cmdPlay.Enabled = False
	'
End Sub

Private Sub cmdRecord_Click()
	'
	If ((ModemCaps And CapSpeakerPhone) <> 0) Then
		If ModemPhone1.SpeakerPhone <> Off Then
			If MsgBox("Recording While The Speaker Phone is On Causes Some Modems to Lock Up" & _
			vbCrLf & "and May Require a Re-Boot and Power Down of the Modem to Reset", vbOKCancel, "WARNING") = vbCancel Then Exit Sub
		End If
	End If
	'
	ModemWave1.RecordFileName = App.Path & "\Record.wav"
	ModemWave1.Record (ModemWaveID)
	cmdRecord.Enabled = False
	'
End Sub

Private Sub cmdStopPlay_Click()
	'
	ModemWave1.StopPlay
	' The DonePlay Event indicates that play has actually ended and that the file has been closed
	'
End Sub

Private Sub CmdStopRecord_Click()
	'
	ModemWave1.StopRecord
	' The DoneRecord Event indicates that recording has actually ended and that the file has been closed
	'
End Sub

Private Sub cmdVolume_Click()
	' Useful for de-bugging but this window is not topped,
	If ModemWave1.VUMetersVisible = True Then
		ModemWave1.VUMetersVisible = False
		cmdVolume.Caption = "Show"
	Else
		ModemWave1.VUMetersVisible = True
		cmdVolume.Caption = "Hide"
	End If
	'
End Sub

Private Sub ModemWave1_DonePlay()
	'
	cmdPlay.Enabled = True
	'
End Sub

Private Sub mnuLocation_Click()
	'
	frmLocation.Show vbModal
	txtCountryCode = ModemPhone1.CountryCode ' preset Current Country Code for Dialling
	txtAreaCode = ModemPhone1.AreaCode ' preset Current Area Code for Dialling
	'
End Sub

Private Sub mnuModem_Click()
	'
	ModemPhone1.ShowModemDialog (Me.hWnd)
	'
End Sub

Private Sub mnuPhone_Click()
	'
	ModemPhone1.ShowPhoneDialog (Me.hWnd)
	'
End Sub

Private Sub mnuSelectModem_Click()
	'
	frmSetup.Show vbModal
	'
End Sub

Private Sub ModemWave1_DoneRecord()
	'
	cmdRecord.Enabled = True
	'
End Sub

Private Sub ModemWave1_SilenceDetection(ByVal Silence As Boolean)
	'
	lblSilence.Visible = Silence
	'
End Sub

Private Sub sldGain_Change()
	'
	If (ModemCaps And CapSpeakerPhoneVolumes) <> 0 Then ' if supported
		ModemPhone1.MicGain = sldGain.Value
	End If
	'
End Sub

Private Sub sldPlayVolume_Change()
	'
	ModemWave1.PlayVolume = sldPlayVolume
	'
End Sub

Private Sub sldRecordVolume_Change()
	'
	ModemWave1.RecordVolume = sldRecordVolume
	'
End Sub

Public Sub OpenModem(ModemID As Long)
	'
	Dim OwnIncoming As Boolean
	Dim OwnPhone As Boolean
	If ModemID = -1 Then ' modem not set yet
		frmSetup.Show vbModal
		Exit Sub
	End If
	'
	If chkOwnIncoming.Value = 1 Then
		OwnIncoming = True
	Else
		OwnIncoming = False
	End If
	'
	If chkOwnPhone.Value = 1 Then
		OwnPhone = True
	Else
		OwnPhone = False
	End If
	'
	ModemCaps = ModemPhone1.GetModemCaps(ModemID) ' Get ModemCaps before opening Modem
	ModemPhone1.OpenModem ModemID, OwnPhone, OwnIncoming
	txtCountryCode = ModemPhone1.CountryCode ' preset Current Country Code for Dialling
	txtAreaCode = ModemPhone1.AreaCode ' preset Current Area Code for Dialling
	'
	GetSpeakerStatus
	GetLocalPhoneStatus
	'
	If (((ModemCaps And CapSpeakerPhoneVolumes) <> 0) And OwnPhone) Then
		' Some modems remember mic gain and speaker volume so:-
		sldGain.Value = ModemPhone1.MicGain ' get current mic gain from modem
		sldVolume.Value = ModemPhone1.SpeakerVolume ' get current speaker volume from modem
	End If
	'
	If (ModemCaps And CapLocalPhone) <> 0 Then ' if supported
		mnuPhone.Enabled = True
	Else
		mnuPhone.Enabled = False
	End If
	'
	If Not (ModemCaps And CapCallerID) <> 0 Then
		txtCallerID.SelText = " Modem Has No Caller ID Capability" & vbCrLf
	End If
	'
End Sub

Private Sub GetSpeakerStatus()
	'
	Dim State
	If (((ModemCaps And CapSpeakerPhone) <> 0) And (chkOwnPhone.Value = 1)) Then
		cmdSPOff.Enabled = True
		cmdSPMic.Enabled = True
		cmdSPSpeaker.Enabled = True
		cmdSPMicSpeaker.Enabled = True
		State = ModemPhone1.SpeakerPhone
		Select Case State
			Case Off
				lblSpeakerState.Caption = "Off"
			Case Mic
				lblSpeakerState.Caption = "Mic On"
			Case Speaker
				lblSpeakerState.Caption = "Speaker On"
			Case MicSpeaker
				lblSpeakerState.Caption = "Mic+Speaker On"
		End Select
		If (ModemCaps And CapSpeakerPhoneVolumes) <> 0 Then
			sldGain.Enabled = True
			sldVolume.Enabled = True
		Else
			sldGain.Enabled = False
			sldVolume.Enabled = False
		End If
	Else
		cmdSPOff.Enabled = False
		cmdSPMic.Enabled = False
		cmdSPSpeaker.Enabled = False
		cmdSPMicSpeaker.Enabled = False
		lblSpeakerState.Caption = "Not Available"
		sldGain.Enabled = False
		sldVolume.Enabled = False
	End If
	'
End Sub

Private Sub GetLocalPhoneStatus()
	'
	Dim State
	If (((ModemCaps And CapLocalPhone) <> 0) And (chkOwnPhone.Value = 1)) Then
		cmdLPOff.Enabled = True
		cmdLPMic.Enabled = True
		cmdLPSpeaker.Enabled = True
		cmdLPMicSpeaker.Enabled = True
		State = ModemPhone1.LocalPhone
		Select Case State
			Case rDevState.Off
				lblPhoneState.Caption = "Off"
			Case rDevState.Mic
				lblPhoneState.Caption = "Mic On"
			Case rDevState.Speaker
				lblPhoneState.Caption = "Speaker On"
			Case rDevState.MicSpeaker
				lblPhoneState.Caption = "Mic+Speaker On"
		End Select
	Else
		cmdLPOff.Enabled = False
		cmdLPMic.Enabled = False
		cmdLPSpeaker.Enabled = False
		cmdLPMicSpeaker.Enabled = False
		lblPhoneState.Caption = "Not Available"
	End If
	'
End Sub

Private Sub sldVolume_Change()
	'
	If (ModemCaps And CapSpeakerPhoneVolumes) <> 0 Then ' if supported
		ModemPhone1.SpeakerVolume = sldVolume.Value
	End If
	'
End Sub

اخي الكريم شكراً لك على الشرح ولكن الاداة التي شرحت عليها غير موجوده على الانترنت بحثت عنها ولم اجدها

وكان طلبي على الاداة Excele Tel Tele Tools v3.7 فحسب كلام الاخوان هي افضل

اتمنى التوضيح ايهم افضل حيث اني اريد استخدامها كالهاتف المصرفي للبنوك ولا مانع عندي ان اتعلم اي اداة تفي بطلبي ولك جزيل الشكر

بالانتظار

الأخوة الأفاضل كيف لى أن أعرف أن المودم الخاص بى به الخاصية DTMF ام لا والتى من خلالها يمكن تتبع ضغطات مفاتيح جهاز التليفون - حسب ما فهمت من هذا الموضوع - علما بأن المودم الخاص بى هو motorola sm56 speaker phone modem

اخواني.

من خلال الروابط التي وضعها والبحث فيها سوف تستطيعون معرفة كل ماتستفسرون عليه

على كل لمعرفة الرقم الذي ضغط عليه المرسل ماعليك سوى الكود التالي

Private Sub etLine_OnDigitReceived(index As Integer, ByVal CallHandle As Long, ByVal Digit As Integer, ByVal Tag As Long)
Select Case Chr(Digit)
Case "#"
msgbox "#"
case "1" 
msgbox "1"

>>>
وهكذا لباقي الارقام
>>>

end select
end sub

اخي الكريم اتمنى توفير وصلة تنزيل الاداة حيث بحثت بالانترنت ولم اجدها

ولك جزيل الشكر

عبدالفتاح حسن كتب:

الأخوة الأفاضل كيف لى أن أعرف أن المودم الخاص بى به الخاصية DTMF ام لا والتى من خلالها يمكن تتبع ضغطات مفاتيح جهاز التليفون - حسب ما فهمت من هذا الموضوع - علما بأن المودم الخاص بى هو motorola sm56 speaker phone modem

المودم الخاص بك يدعم هذه الخاصية

zaid000 كتب:

اخي الكريم اتمنى توفير وصلة تنزيل الاداة حيث بحثت بالانترنت ولم اجدها

ولك جزيل الشكر

الوصلة موجود في المشاركات الاولى لنفس الموضوع وهي شغالة

اخي الكريم g-johnny الكود الذي وضعته لا يعمل لدي وبالتحديد الحدث OnDigitReceived لا يعمل حتى اني تعمدة على اي رقم يضغط ولكن لا يستجيب للاحداث

مع ملاحظة ما يلي

قمت بتفعيل المودم وتحديده وقمة ايضاً بتجربة اخرى بفتح الرد الآلي وقمت بالضغط على عدة ارقام ولا فائدة فاين الخطاء؟

سيدي العزيز مهندس الاتصال (h)

اشكرك من كل اعماق قلبي

فانت لاتتخيل عن مدي شكري لك علي هذا الكود الجميل وزادك الله من علمة ;)

اخي العزيز كفيت ماقصرت وقد استفت من هذا الكود ولاقيت الجواب الشافي من خلال مناقشاتك وطرح الاخوان الاعزاء

وقد قمت بتحويلة الي لغة ال سي ++ وعمل الكود وتحسس الارقام التلفونية

مشكور لك والاخوة والمشرفين

حيث واني مازلت في طور التجهيز

وياريت تعطيني فكرة او كود تكملة للاول فية استطيع سماع الرسالة الصوتية .wav او استقبالها عبر خط الهاتف (المودم)

فهناك نوع 1-عبر الميكرون والهاند

2- وهنالك تسجيل وسماع عبر خط المودم

مالفرق وكيف التعامل مع النوع الثاني ياريت كود والخصائص

وسامحني من التثقيل عليك

اخوك قاهر العذاراء

اخواني واخواتي بهذ المنتدي احب اعرض عليكم خدماتي بهذ المجال انا لدي اجهزة توفر خدمة اظهار رقم المتصل ومفتوح المصدر وممكن التعاون معكم لحل مشكلة اظهار رقم المتصل بعيد عن المودم ومن خط الى 64 وعلى الكوم او USB بعد اذن المشرفين والقائمين على هذا المنتدى فقط مسا عدة

نجتاج لما تفضلت به يا استاذ عوض القحطاني ضورري ان تشرح لنا ما تعلم عنه جزاك الله خير فانا من المتطلعين لمثل هذه الامور :(

السلام عليكم

اخواني الاعزاء قمت منذ فترة بفتح هذا الموضوع

حيث قمت بإرفاق الاداة و مثال عليها

و هي اداة ممتازة و مجربة 100 % بدليل ان اكثر من 1600 شخص قاموا بعمل Download لها

و هذا رابط الموضوع

الرابط

مثال لإظهار رقم المتصل CallerID بدون أدوات إضافية: Modem CallerID