المساعده في تعديل كود الحذف

أظن -والله أعلم- أن الشفرة قد تعمل هكذا

Dim db As Database, rs As Recordset
    Set db = CurrentDb
    Set rs = db.OpenRecordset("Control_sheet")
    With rs
        While Not .EOF
            If .PV = 1 Then
                .Delete
            End If
            .MoveNext
        Wend
    End With
  

    MsgBox "انتهى الحذف"

اخي العزيز جزاك الله خيرا

هذا الكود جربته مسبقا ولم يعمل وجربته مرة ثانية للتاكد ولم يعمل

قمت بعدة تجارب ولم اصل الى مبتغاي

بانتظار المزيد

مرررررررررة اخرى

لقد قمت باعادة المحاولة وهي كالتالي

في الجدول المراد الحذف منه توجد حقول فارغة وقمت بملء الحقول وقام بالحذف

ما ابحث عنه

كيف تبحث قيمة معينة في الجدول

عن طريق seek

أخي الكريم...

لم أعمل بال DAO، ولكن يبدو أن استعمال طريقة seek في ال DAO (كما في ADO) تشترط استعمال مجموعة سجلات مفهرسة (باستخدام الخاصية Index)...

وعلى كل حال خذ هذا المثال من تعليمات الأكسس يوضح استخدام الـ seek في DAO:

Seek Method Example

This example demonstrates the Seek method by allowing the user to search for a product based on an ID number.

Sub SeekX()

    Dim dbsNorthwind As Database
    Dim rstProducts As Recordset
    Dim intFirst As Integer
    Dim intLast As Integer
    Dim strMessage As String
    Dim strSeek As String
    Dim varBookmark As Variant

    Set dbsNorthwind = OpenDatabase("Northwind.mdb")
    ' You must open a table-type Recordset to use an index, 
    ' and hence the Seek method.
    Set rstProducts = _
        dbsNorthwind.OpenRecordset("Products", dbOpenTable)

    With rstProducts
        ' Set the index.
        .Index = "PrimaryKey"

        ' Get the lowest and highest product IDs.
        .MoveLast
        intLast = !ProductID
        .MoveFirst
        intFirst = !ProductID

        Do While True
            ' Display current record information and ask user 
            ' for ID number.
            strMessage = "Product ID: " & !ProductID & vbCr & _
                "Name: " & !ProductName & vbCr & vbCr & _
                "Enter a product ID between " & intFirst & _
                " and " & intLast & "."
            strSeek = InputBox(strMessage)

            If strSeek = "" Then Exit Do

            ' Store current bookmark in case the Seek fails.
            varBookmark = .Bookmark

            .Seek "=", Val(strSeek)

            ' Return to the current record if the Seek fails.
            If .NoMatch Then
                MsgBox "ID not found!"
                .Bookmark = varBookmark
            End If
        Loop

        .Close
    End With

    dbsNorthwind.Close

End Sub