تحويل الأرقام الى حروف باللغة الإنجليزية

هل تقصد اخي ASCII code

انا لم افهم قصدك?

اخي الفاضل

السلام عليكم ورحمة الله وبركاته

للقيام بعملية تحويل الارقام الى حروف انجليزيه تحتاج الى الآتي

1. وحدة نمطية جديده

2. نموذج به مربعين نص

ضع في الوحدة النمطية الجديده هذا الكود

Option Compare Database
Option Explicit
Function ConvertCurrencyToEnglish(ByVal MyNumber)
   Dim Temp
   Dim Riyals, Halals
   Dim DecimalPlace, Count

   ReDim Place(9) As String
   Place(2) = " Thousand "
   Place(3) = " Million "
   Place(4) = " Billion "
   Place(5) = " Trillion "

   ' Convert MyNumber to a string, trimming extra spaces.
   MyNumber = Trim(Str(MyNumber))

   ' Find decimal place.
   DecimalPlace = InStr(MyNumber, ".")

   ' If we find decimal place...
   If DecimalPlace > 0 Then
      ' Convert Halals
      Temp = Left(Mid(MyNumber, DecimalPlace + 1) & "00", 2)
      Halals = ConvertTens(Temp)

      ' Strip off cents from remainder to convert.
      MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
   End If

   Count = 1
   Do While MyNumber <> ""
      ' Convert last 3 digits of MyNumber to English Riyals.
      Temp = ConvertHundreds(Right(MyNumber, 3))
      If Temp <> "" Then Riyals = Temp & Place(Count) & Riyals
      If Len(MyNumber) > 3 Then
         ' Remove last 3 converted digits from MyNumber.
         MyNumber = Left(MyNumber, Len(MyNumber) - 3)
      Else
         MyNumber = ""
      End If
      Count = Count + 1
   Loop

   ' Clean up Riyals.
   Select Case Riyals
      Case ""
         'Riyals = "No Riyals"
      Case "One"
         Riyals = "One Riyal"
      Case Else
         Riyals = Riyals & " Riyals"
   End Select

   ' Clean up Halals.
   Select Case Halals
      Case ""
         'Halals = " And No Halals"
      Case "One"
         Halals = " And One Halalh"
      Case Else
         Halals = " And " & Halals & " Halals"
   End Select

   ConvertCurrencyToEnglish = Riyals & Halals
End Function

Private Function ConvertHundreds(ByVal MyNumber)
   Dim Result As String

   ' Exit if there is nothing to convert.
   If Val(MyNumber) = 0 Then Exit Function

   ' Append leading zeros to number.
   MyNumber = Right("000" & MyNumber, 3)

   ' Do we have a hundreds place digit to convert?
   If Left(MyNumber, 1) <> "0" Then
      Result = ConvertDigit(Left(MyNumber, 1)) & " Hundred "
   End If

   ' Do we have a tens place digit to convert?
   If Mid(MyNumber, 2, 1) <> "0" Then
      Result = Result & ConvertTens(Mid(MyNumber, 2))
   Else
      ' If not, then convert the ones place digit.
      Result = Result & ConvertDigit(Mid(MyNumber, 3))
   End If

   ConvertHundreds = Trim(Result)
End Function

Private Function ConvertTens(ByVal MyTens)
   Dim Result As String

   ' Is value between 10 and 19?
   If Val(Left(MyTens, 1)) = 1 Then
      Select Case Val(MyTens)
         Case 10: Result = "Ten"
         Case 11: Result = "Eleven"
         Case 12: Result = "Twelve"
         Case 13: Result = "Thirteen"
         Case 14: Result = "Fourteen"
         Case 15: Result = "Fifteen"
         Case 16: Result = "Sixteen"
         Case 17: Result = "Seventeen"
         Case 18: Result = "Eighteen"
         Case 19: Result = "Nineteen"
         Case Else
      End Select
   Else
      ' .. otherwise it's between 20 and 99.
      Select Case Val(Left(MyTens, 1))
         Case 2: Result = "Twenty "
         Case 3: Result = "Thirty "
         Case 4: Result = "Forty "
         Case 5: Result = "Fifty "
         Case 6: Result = "Sixty "
         Case 7: Result = "Seventy "
         Case 8: Result = "Eighty "
         Case 9: Result = "Ninety "
         Case Else
      End Select

      ' Convert ones place digit.
      Result = Result & ConvertDigit(Right(MyTens, 1))
   End If

   ConvertTens = Result
End Function

Private Function ConvertDigit(ByVal MyDigit)
   Select Case Val(MyDigit)
      Case 1: ConvertDigit = "One"
      Case 2: ConvertDigit = "Two"
      Case 3: ConvertDigit = "Three"
      Case 4: ConvertDigit = "Four"
      Case 5: ConvertDigit = "Five"
      Case 6: ConvertDigit = "Six"
      Case 7: ConvertDigit = "Seven"
      Case 8: ConvertDigit = "Eight"
      Case 9: ConvertDigit = "Nine"
      Case Else: ConvertDigit = ""
   End Select
End Function

العملة الموجوده هي الريال والهلله Riyal و Halalh

تستطيع تغييرها بما لديك سواء دولار وسنت او دينار وفلس او درهم او جنيه وقرش ( حاول تتبع سياق العملة سواء مفرد او جمع )

في النموذج ضع مربعين نص

الاول : اسمه Number

والثاني : اسمه Convert

في مربع النص الثاني اجعل مصدر عنصر التحكم هذا الامر

=ConvertCurrencyToEnglish(NZ([Number]))

وهذا مثال مرفق

Convert_Numbers_into_English_Words.rar

اختكم

زهره

شكراً الأخت زهرة

هذا ماأردته