وضع كلمة سر علس شاشة الويندوز Me,98

الأستاذة الفاضلة / زهرة

السلام عليكم ورحمة الله وبركاته وكل عام وسيادتكم بخير بمناسبة عيد الفطر المبارك اعاده الله عليكي وعلينا بالخير واليمن والبركات

البداية

برنامج صغير يمنع كتابة أسمي محمد جلال يمنع الحروف ويمنع إستخدام alt+f4

أرجو توضيح كود إنهاء ويندوز باقي الحروف ملم بها ما عدا حركة إنهاء الويندوز

أخيكم

محمد جلال

galal.rar

اخي محمد جلال

السلام عليكم ورحمة الله وبركاته

من اجل وضع زر امر لاغلاق الاكسيس مع الويندوز يجب ان نقوم بعدة امور تسبق هذا الحدث

1. لابد لنا من اخفاء شاشة الاكسيس اولا بواسطة الكود

2. لابد لنا من تكبير النموذج الى اقصى حد ممكن بواسطة الكود

3. لابد من ازالة بعض الخصالص من النموذج

4. ترتيب الاحداث بالتسلسل فلا نقدم حدث معين على اخر حتى لا نقع في مشاكل

5. وضع اختصار على سطح المكتب للقاعدة او البرنامج ومن ثم وضعه في بدء التشغيل للويندوز

اليك الخطوات بالتفصيل

قم بإنشاء وحدة نمطية جديده بإسم api_ShowWindow

وضع بها هذا الكود

Option Compare Database
Option Explicit

Global Const SW_HIDE = 0
Global Const SW_SHOWNORMAL = 1
Global Const SW_SHOWMINIMIZED = 2
Global Const SW_SHOWMAXIMIZED = 3

Private Declare Function apiShowWindow Lib "User32" _
    Alias "ShowWindow" (ByVal hWnd As Long, _
          ByVal nCmdShow As Long) As Long

Function fSetAccessWindow(nCmdShow As Long)
'Usage Examples
'Maximize window:
'       ?fSetAccessWindow(SW_SHOWMAXIMIZED)
'Minimize window:
'       ?fSetAccessWindow(SW_SHOWMINIMIZED)
'Hide window:
'       ?fSetAccessWindow(SW_HIDE)
'Normal window:
'       ?fSetAccessWindow(SW_SHOWNORMAL)
'
Dim loX  As Long
Dim loForm As Form
    On Error Resume Next
    Set loForm = Screen.ActiveForm
    If Err <> 0 Then 'no Activeform
      If nCmdShow = SW_HIDE Then
        'MsgBox "Cannot hide Access unless " _
                    & "a form is on screen"
      Else
        loX = apiShowWindow(hWndAccessApp, nCmdShow)
        Err.Clear
      End If
    Else
        If nCmdShow = SW_SHOWMINIMIZED And loForm.Modal = True Then
            'MsgBox "Cannot minimize Access with " _
                    & (loForm.Caption + " ") _
                    & "form on screen"
        ElseIf nCmdShow = SW_HIDE And loForm.PopUp <> True Then
            'MsgBox "Cannot hide Access with " _
                    & (loForm.Caption + " ") _
                    & "form on screen"
        Else
            loX = apiShowWindow(hWndAccessApp, nCmdShow)
        End If
    End If
    fSetAccessWindow = (loX <> 0)
End Function

فائدة هذا الكود يقوم بإخفاء برنامج الاكسيس والابقاء على النموذج مفتوح في وضع التكبير لاقصى حد ممكن ويتطلب بعض الاضافات ليعمل :

انتقل الى خصائص النموذج وقم بعمل التالي من التبويب الكل

1. اشرطة التمرير لا هذا ولا ذاك

2. محددات السجلات لا

2. ازرار التنقل لا

3. الخطوط المقسمه لا

4. تغيير حجم تلقائي نعم

5. توسيط تلقائي نعم

6. منبثق نعم

7. شكلي او مشروط نعم

8. نمط الحدود بلا

9. مربع عنصر التحكم لا

10. زر التصغير والتكبير لا

11. زر الاغلاق لا

انتقل الان الى التبويب حدث واختر حدث في الحالي وضع هذا الكود

Private Sub Form_Current()
'تكبير النموذج لاقصى حد ممكن
        fSetAccessWindow (SW_SHOWMAXIMIZED)
'اخفاء برنامج الاكسيس
       fSetAccessWindow (SW_HIDE)
End Sub

وايضا ضع هذا الكود في حدث عند الفتح

Private Sub Form_Open(Cancel As Integer)
DoCmd.Maximize
End Sub

قم بإنشاء وحدة نمطية جديده بإسم WinExit

وضع بها هذا الكود

Option Compare Database
Declare Function ExitWindowsEx Lib "User32" (ByVal uFlags As _
Long, ByVal dwReserved As Long) As Long
Function ShutDownWindows()
   'This will quit all applications and shut down Windows.
   Dim X As Long
   X = ExitWindowsEx(0, 0)
   Application.Quit acExit
End Function

الان انتقل للتموذج وقم بإنشاء بزر امر خروج ثم ضع به هذا الكود

Call ShutDownWindows

الخطوة الاخيره

انتقل الى اشرطة ادوات الاكسيس العلوية واختر ادوات ثم بدء التشغيل :

1. قم بجعل النموذج المطلوب هو بدء التشغيل من خانة عرض النموذج او الصفحة

2. قم بإزالة جميع علامات الصح من اللوحة ثم موافق

3. الان انتهينا تقريبا من جميع الخطوات نقوم الان بعمل اختصار لقاعدة البيانات على سطح المكتب ثم ننسخ هذا الاختصار ونضعه في بدء التشغيل الخاص بالويندوز .

3. تحذير قم بحفظ كل شيء سواء ملفات نصية او صفحات لانك بعد تشغيل برنامج الاكسيس لن تستطيع الخروج الا عن طريق زر الاغلاق بمعنى لا تترك شيء مفتوح .

3. قم بإعادة تشغيل الويندوز وستجد ان نموذج القاعدة هو اول ما يفتح لك ولن تخرج منه الا بكتابة الرقم السري الصحيح او اغلاق الويندوز والاكسيس معا من خلال زر الامر .

وهذا ملفك بعد التعديل

galal.rar

نركت لك زر مفتاح الشفت Shift مفتوح اذا رغبت بالتعديل على القاعدة والدخول اليها اضغط مقتاح الشفت من لوحة المفاتيح ومن ثم قم بتشغيل القاعدة .

اختكم

زهره

الحمد لله والشكر لله علي جميع نعمه

ولك الف شكر علي كل ما تقدمين خير

أخيكم

محمد جلال