توسيط النص داخل أداة Edit

ال TEdit لا يوجد به خاصية تسمى Alignment لكن يمكنك اضافتها بسهولة من خلال اشتقاقها من صنف ال TEdit، وهذا مثال لمكون جديد به هذه الخاصية

unit mnEdit;

interface

uses
  SysUtils, Classes, Controls, StdCtrls, Windows;

type
  TmnEdit = class(TEdit)
  private
    FAlignment: TAlignment;
    procedure SetAlignment(Value: TAlignment);
  protected
    procedure CreateParams(var Params: TCreateParams); override;
  public
    property Alignment: TAlignment read FAlignment write SetAlignment;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('mnEdit', [TmnEdit]);
end;

{ TmnEdit }

procedure TmnEdit.CreateParams(var Params: TCreateParams);
const
  Alignments : array[TAlignment] of LongWord= (ES_Left,ES_Right, ES_Center);
begin
  inherited CreateParams(Params);
  Params.Style := Params.Style or Alignments[FAlignment];
end;

procedure TmnEdit.SetAlignment(Value: TAlignment);
begin
  if FAlignment <> Value then
  begin
    FAlignment := Value;
    RecreateWnd;
  end;
end;

end.

ايضا هناك طريقة اخرى وهي ان تقوم بتعريف TEdit مرة اخرى مثلا ضمن النموذج الذى تستخدمه وهذه سوف يقوم بعمل override للنسخة الموجودة ضمن دلفي وسوف تضاف الخاصية تلقائياً ل Tedit ولن تحتاج لاضافة مكون جديد