كود القفل و اعادة التحميل

اخي هناك موضوع لي في المنتدى وهو مكتبة اكواد ابحث عنه وحملها وسوف تجد فيها ما تريد إن شاء الله :)

يمكنك عمل ذلك بواسطه دوال api

وهذا تعريفها

' Constantالثوابت
Const SE_PRIVILEGE_ENABLED As Integer = &H2
Const TOKEN_QUERY As Integer = &H8
Const TOKEN_ADJUST_PRIVILEGES As Integer = &H20
Const SE_SHUTDOWN_NAME As String = "SeShutdownPrivilege"
' Exit Windows Constants
Const EWX_LOGOFF As Integer = &H0
Const EWX_SHUTDOWN As Integer = &H1
Const EWX_REBOOT As Integer = &H2
Const EWX_FORCE As Integer = &H4
Const EWX_POWEROFF As Integer = &H8
Const EWX_FORCEIFHUNG As Integer = &H10
'Structure
<StructLayout(LayoutKind.Sequential, Pack:=1)> _
Friend Structure Luid
   Public Count As Integer
   Public Luid As Long
   Public Attr As Integer
End Structure 'TokPriv1Luid
'تعريف الاجراءات
' Get Current Processes.  .
<DllImport("kernel32.dll", ExactSpelling:=True)> _
Function GetCurrentProcess() As IntPtr
End Function

' Open Process Token.  .
<DllImport("advapi32.dll", SetLastError:=True)> _
Function OpenProcessToken(ByVal h As IntPtr, ByVal acc As Integer, ByRef phtok As IntPtr) As Boolean
End Function

' Look up Priviledge Value.  .
<DllImport("advapi32.dll", SetLastError:=True)> _
Friend Function LookupPrivilegeValue(ByVal host As String, ByVal name As String, ByRef pluid As Long) As Boolean
End Function

' Adjust Token Priviledges.  .
<DllImport("advapi32.dll", ExactSpelling:=True, SetLastError:=True)> _
Friend Function AdjustTokenPrivileges(ByVal htok As IntPtr, ByVal disall As Boolean, ByRef newst As Luid, ByVal len As Integer, ByVal prev As IntPtr, ByVal relen As IntPtr) As Boolean
End Function

' Exit Windows  .
<DllImport("user32.dll", ExactSpelling:=True, SetLastError:=True)> _
Friend Function ExitWindowsEx(ByVal flg As Integer, ByVal rea As Integer) As Boolean
End Function


' Exit Windows Sub
Private Sub DoExitWindows(ByVal flg As Integer)
  Dim tp As Luid
  Dim hproc As IntPtr = GetCurrentProcess()
  Dim htok As IntPtr = IntPtr.Zero

  'Get a token for this process. 
  OpenProcessToken(hproc, TOKEN_ADJUST_PRIVILEGES Or TOKEN_QUERY, htok)
  tp.Count = 1
  tp.Luid = 0
  tp.Attr = SE_PRIVILEGE_ENABLED

  'Get the LUID for the shutdown privilege.
   LookupPrivilegeValue(Nothing, SE_SHUTDOWN_NAME, tp.Luid)

   'Get the shutdown privilege for this process.
   AdjustTokenPrivileges(htok, False, tp, 0, IntPtr.Zero, IntPtr.Zero)

  'Exit Windows
  ExitWindowsEx(flg, 0)
End Sub

'استدعاء الاجراءات
' Shutdownاغلاق
DoExitWindows(EWX_SHUTDOWN)

' Restartاعادة تشغيل
DoExitWindows(EWX_REBOOT Or EWX_FORCE)

' Log offتسجيل الخروج
DoExitWindows(EWX_LOGOFF)

الكود السابق يعمل على كل انظمة nt اما اذا كنت ستعمل فقط على انظمة windows 9x فهذا الكود يفى بالغرض

Const EWX_LogOff As Long = 0
       Const EWX_SHUTDOWN = 1
       Const EWX_REBOOT = 2
       Const EWX_FORCE = 4
       Private Declare Function ExitWindows _
               Lib "User32" Alias "ExitWindowsEx" _
               (ByVal dwOptions As Long, ByVal dwReserved As Long) As Long

اغلاق الجهاز

ExitWindows (EWX_SHUTDOWN, &HFFFFFFFF)

اعادة التشغيل

ExitWindows (EWX_REBOOT, &HFFFFFFFF)

السلام عليكم و رحمة الله

اشكر كل من ساهم في الاجابة الا انها مطولة و في رأي توجد طريقة اسهل و هي امر دوس

shutdown -s -t 0 من أجل ايقاف التشغيل و

shutdown -l لتسجيل الخروج و

shutdown -r لاعادة التشغيل

كيف يمكن تنفيذ أوامر Dos

في دوت نت

وشكرا

السلام عليكم و رحمة الله و بركاته

يمكن عن طريق shell

عمرو عيسي