جعل برنامجك يشتغل عند بدء التشغيل

جاري التجربه

وساتيك بالرد

شكار لك للمرور والرد

منتظر رأيك

10\10

الان اجربه

وأي سؤال سنحاول الإجابة عنه

ملاحظة:

استخدمت هنا HKEY_CURRENT_USER وذلك لجعل البرنامج في بدء التشغيل للمستخدم الحالي حيث يمكنك استخدام HKEY_LOCAL_MACHINE لوضعه في بدء التشغيل لكافة المستخدمين طبعا مع امتلاك المستخدم الذي سجلت الدخول به في الويندوز للصلاحيات اللازمة

وهذا إجراء معدل بدون الكلاس المذكور في مشاركتي الأولى

في الإعلانات العامة

Imports Microsoft.Win32
Imports System.Windows.Forms

وهذا هو الاجراء

    Public Sub RunatStartup(ByVal PutAtStartup As Boolean, ByVal ProgramName As String)
        Dim StartupPath As String = "Software\Microsoft\Windows\CurrentVersion\Run"
        Dim MyKey As RegistryKey = Registry.CurrentUser.OpenSubKey(StartupPath, True)

        If PutAtStartup Then
            MyKey.SetValue(ProgramName, Application.ExecutablePath)
        Else
            Try
                MyKey.DeleteValue(ProgramName, False)
            Catch ex As Exception
                ex = Nothing
            End Try
        End If

    End Sub

وهذا مثال عن الاستخدام وضعه في بدء التشغيل

RunatStartup(True, "Test Application")

وهذا مثال عن الاستخدام إزالته من بدء التشغيل

RunatStartup(False, "Test Application")

و لجعله في بدء التشغيل لكافة المستخدمين بدل المستخدم الحالي ضع السطر

Dim MyKey As RegistryKey = Registry.LocalMachine.OpenSubKey(StartupPath, True)

بدلا عن السطر

        Dim MyKey As RegistryKey = Registry.CurrentUser.OpenSubKey(StartupPath, True)

وذلك في الاجراء المذكور هنا

أي يصبح الإجراء

    Public Sub RunatStartup(ByVal PutAtStartup As Boolean, ByVal ProgramName As String)
        Dim StartupPath As String = "Software\Microsoft\Windows\CurrentVersion\Run"
        Dim MyKey As RegistryKey = Registry.LocalMachine.OpenSubKey(StartupPath, True)

        If PutAtStartup Then
            MyKey.SetValue(ProgramName, Application.ExecutablePath)
        Else
            Try
                MyKey.DeleteValue(ProgramName, False)
            Catch ex As Exception
                ex = Nothing
            End Try
        End If

    End Sub

ويبقى الاستخدام ذات نفسه

Greaaaaaaaaaaat

but why didn't u use the Try statement with the following line in the last example:

If PutAtStartup Then
           MyKey.SetValue(ProgramName, Application.ExecutablePath)
       Else

أولا يرجى الكتابة بالعربية

ثانيا - لم اجد داعي الاستخدام try عند هذا السطر لأنه اثناء تجاربي لم يظهر exception عنده حتى في حالة عدم وجود المفتاح المطلوب فقد لاحظت انه يتم إنشاؤه و لكن ذلك لايمنعك من استخدامه

وإذا حدا واجه مشاكل

هي مثالين بالـ 2005 و الـ 2003

مع أني بعتقد أنو الشرح واضح

TestStartup_Vb2005.zip

TestStartup_vb2003.zip

جزاك الله كل خير

كما يمكن التأكد من وجود البرنامج في بدء التشغيل كما يلي

   Public Function CheckRunAtStartup(ByVal ProgramName As String) As Boolean
		Dim StartupPath As String = "Software\Microsoft\Windows\CurrentVersion\Run"
		Dim MyKey As RegistryKey = Registry.CurrentUser.OpenSubKey(StartupPath, False)

		If MyKey.GetValue(ProgramName, "") = Application.ExecutablePath Then
			Return True
		Else
			Return False
		End If
	End Function

وهذا إجراء مطور مع بعض الخيارات الإضافية لوضع البرنامج في بدء التشغيل والتأكد من وجوده في بدء التشغيل

	' تحديد مكان وضع البرنامج في بدء التشغيل
	Public Enum StartupPlace
		Currentuser
		LocalMachine
	End Enum

	' الاجراء الذي سيقوم بوضع برنامجك في بدء التشغيل
	Public Sub RunatStartup(ByVal PutAtStartup As Boolean, _
							ByVal ProgramName As String, _
						   Optional ByVal StartPlace As StartupPlace = StartupPlace.Currentuser, _
						   Optional ByVal CommandLineArguments As String = "")

		Try
			' تحديد المسار ضمن الريجستري
			Dim StartupPath As String = "Software\Microsoft\Windows\CurrentVersion\Run"
			' تحديد مكان المفتاح
			Dim MyKey As RegistryKey
			Select Case StartPlace
				Case StartupPlace.Currentuser
					' المستخدم الحالي
					MyKey = Registry.CurrentUser.OpenSubKey(StartupPath, True)
				Case StartupPlace.LocalMachine
					' جميع المستخدمين
					MyKey = Registry.LocalMachine.OpenSubKey(StartupPath, True)
			End Select

			If PutAtStartup Then
				' إنشاء المفتاح المناسب لوضع البرنامج في بدء التشغيل
				MyKey.SetValue(ProgramName, """" & Application.ExecutablePath & """" & " " & CommandLineArguments)
			Else
				' حذف المفتاح لإزالة البرنامج من بدء التشغيل
				MyKey.DeleteValue(ProgramName, False)
			End If
		Catch ex As Exception
			MsgBox(ex.Message)
		End Try
	End Sub

	' التأكد من وجود برنامجك في بدء التشغيل
	Public Function CheckRunAtStartup(ByVal ProgramName As String, _
			Optional ByVal StartPlace As StartupPlace = StartupPlace.Currentuser) As Boolean

		Try
			' تحديد المسار ضمن الريجستري
			Dim StartupPath As String = "Software\Microsoft\Windows\CurrentVersion\Run"

			' تحديد مكان المفتاح
			Dim MyKey As RegistryKey
			Select Case StartPlace
				Case StartupPlace.Currentuser
					' المستخدم الحالي
					MyKey = Registry.CurrentUser.OpenSubKey(StartupPath, True)
				Case StartupPlace.LocalMachine
					' جميع المستخدمين
					MyKey = Registry.LocalMachine.OpenSubKey(StartupPath, True)
			End Select

			' إذا كانت قيمة المفتاح مساوية للمسار الكامل للبرنامج
			Dim KeyVal As String = MyKey.GetValue(ProgramName, String.Empty)
			If KeyVal <> String.Empty AndAlso KeyVal.IndexOf(Application.ExecutablePath) <> -1 Then
				Return True
			Else
				Return False
			End If
		Catch ex As Exception
			MsgBox(ex.Message)
		End Try
	End Function

وهذه أمثلة عن استخدام الإجراء المطور

	Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
		' وضع في بدء التشغيل بدون بارامترات سطر الأوامر عند التشغيل
		If Me.RadioButton1.Checked Then
			' المستخدم الحالي
			RunatStartup(True, "اسم برنامجك هنا")
		ElseIf Me.RadioButton2.Checked Then
			' جميع المستخدمين
			RunatStartup(True, "اسم برنامجك هنا", StartupPlace.LocalMachine)
		End If
	End Sub

	Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
		' إزالة من بدء التشغيل
		If Me.RadioButton1.Checked Then
			' المستخدم الحالي
			RunatStartup(False, "اسم برنامجك هنا")
		ElseIf Me.RadioButton2.Checked Then
			' جميع المستخدمين
			RunatStartup(False, "اسم برنامجك هنا", StartupPlace.LocalMachine)
		End If
	End Sub

	Private Sub Button3_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button3.Click
		' تفحص وجوده في بدء التشغيل
		If Me.RadioButton1.Checked Then
			' المستخدم الحالي
			MsgBox(CheckRunAtStartup("اسم برنامجك هنا"))
		ElseIf Me.RadioButton2.Checked Then
			' جميع المستخدمين
			MsgBox(CheckRunAtStartup("اسم برنامجك هنا", StartupPlace.LocalMachine))
		End If
	End Sub

	Private Sub Button4_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button4.Click
		' وضع في بدء التشغيل مع بارامترات سطر الأوامر عند التشغيل
		If Me.RadioButton1.Checked Then
			' المستخدم الحالي
			RunatStartup(True, "اسم برنامجك هنا", StartupPlace.Currentuser, " /Test /Minimize")
		ElseIf Me.RadioButton2.Checked Then
			' جميع المستخدمين
			RunatStartup(True, "اسم برنامجك هنا", StartupPlace.LocalMachine, " /Test /Minimize")
		End If
	End Sub