ممكن كود ساعه بالارقام عبر اداة التايمر ثوانى - دس

اعضاء ومشرفي منتدى الفيجول بيسك

اختكم زهره من مبرمجي الاكسس في منتدى قواعد البيانات للاكسس للفريق العربي للبرمجه .

احببت مشاركتكم البسيطه لغرض التجربه بعد ان رأيت سؤال الاخ الفاضل وكذلك للتأكد من اكواد الفيجول بيسك اكسس تتماشى مع اكواد الفيجول بيسك وقمت بعمل هذا النموذج لساعه تايمر " عداد وقت "

وهذا هو الكود

Option Compare Database
Option Explicit

Dim TotalElapsedMilliSec As Long
Dim StartTickCount As Long
Private Declare Function GetTickCount Lib "kernel32" () As Long

Private Sub cmdStartStop_Click()
    If Me.TimerInterval = 0 Then
        StartTickCount = GetTickCount()
        Me.TimerInterval = 15
        Me!cmdStartStop.Caption = "ايقاف&"
        Me.cmdStartStop.ForeColor = RGB(255, 0, 0)
        Me.cmdStartStop.FontSize = "16"
        Me!cmdReset.Enabled = False
    Else
        TotalElapsedMilliSec = TotalElapsedMilliSec + (GetTickCount() - StartTickCount)
        Me.TimerInterval = 0
        Me!cmdStartStop.Caption = "ابــــدأ"
        Me.cmdStartStop.ForeColor = RGB(255, 0, 0)
        Me.cmdStartStop.FontSize = "16"
        Me!cmdReset.Enabled = True
    End If
End Sub
Private Sub cmdClose_Click()
    DoCmd.Close acForm, "frmStopWatch", acSaveNo
End Sub

Private Sub Form_Timer()
    Dim Hours As String
    Dim Minutes As String
    Dim Seconds As String
    Dim MilliSec As String
    Dim Msg As String
    Dim ElapsedMilliSec As Long
    
    ElapsedMilliSec = (GetTickCount() - StartTickCount) + TotalElapsedMilliSec
    
    Hours = Format((ElapsedMilliSec \ 3600000), "00")
    Minutes = Format((ElapsedMilliSec \ 60000) Mod 60, "00")
    Seconds = Format((ElapsedMilliSec \ 1000) Mod 60, "00")
    MilliSec = Format((ElapsedMilliSec Mod 1000) \ 10, "00")
    
    Me!ElapsedTime = Hours & ":" & Minutes & ":" & Seconds & ":" & MilliSec
    
End Sub

Private Sub cmdReset_Click()
    TotalElapsedMilliSec = 0
    Me!ElapsedTime = "00:00:00:00"
End Sub

وختاما لكم شكري وتقديري

اختكم المخلصه

زهره

وهذا المثال مرفق

stopwatch.zip

تفضل اخى rockmafja

ارجو لك التوفيق :)

DigitalClock.zip

شكرا للاخت زهرا

وشكرا جزيلا لك اخى MSrahieb_100

وكل سنه وانتوا بخير