رجاء رجاء يا شباب؟؟؟؟؟؟؟؟؟؟؟؟؟؟؟؟

أخي هذه ثلاثة طلبات في واحد :)

اعمل صفحة سميها count.asp يكون فيها الآتي:

<%

' Every time we count a user we will put the 
' latest count value in the session variable "TotalCount"
' If Session Variable TotalCount is empty
' that mean this user is new and session variable
' But if Session Variable already has the value
' Then we will not count this user again.

If IsEmpty(Session("TotalCount"))  Then  
 Call CountThisUser
End If

' It is good practice to use Functions and Sub procedure
' Because all the variables being used in sub or function 
' are automatically destroyed when Sub or Function finish 
' processing the code.
' So you can use these Variables again in other functions
Sub CountThisUser()

 Dim objFSO           ' FileSystemObject
 Dim objTS            ' TextStreamObject

 Dim strFileName      ' Counter text File Name
 Dim intOldCount
 Dim intNewCount
   
 ' Specify the Text file to store count value
 ' Because We Set Create = True
 ' File will be Created if it does not exist
  
 strFileName = Server.MapPath("Counter.txt")
  
 Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
  
 If objFSO.FileExists(strFileName)  Then
  Set objTS = objFSO.OpenTextFile(strFileName, 1)
 Else
  Set objTS = objFSO.CreateTextFile(strFileName, True)
 End If
     
 If Not objTS.AtEndOfStream  Then
  intoldCount = objTS.ReadAll
 Else
  intoldCount = 0
 End If
  
 objTS.Close
    
 intNewCount = intOldCount + 1
    
 ' Store the value of intNewCount in Session Variable 
 ' So you can use it on different pages
 Session("TotalCount")= intNewCount
    
 ' Write intNewCount value back to text file
  
 Set objTS = objFSO.CreateTextFile(strFileName, True)
 objTS.Write intNewCount
  
 objTS.Close
  
 Set objFSO = Nothing
 Set objTS = Nothing
End Sub
%>

أضف هذه الصفحة إلى كل صفحة من موقعك أو الـ header كالتالي:

<!--#Include File="Count.asp"-->

ثم اعرض النتيجة بواسطة:

<%=Session("TotalCount")%>

مثال عن كود العرض:

<HTML>
<HEAD>
<TITLE>Display user Count</TITLE>
<!--#Include File="Count.asp"-->
</HEAD>
<BODY>
<Center>
<H1>Welcome to DevASP.com</H1>
<H2>You are User Number<%=Session("TotalCount")%></H2>
</Center>
</BODY>
</HTML>

بدلاً من إعادة الكتابة هذا الكلام مأخوذ من:

http://www.devasp.com/samples/counter.asp

شكرا لك اخ محمد القرني ساجرب الكود وإلك الحلوان إزا زبط!!!!

بالتوفيق إن شاء الله. على فكرة الاسم هو محمد القربي (باء ياء)

:)

قد لا حظت أنك سئلت نفس السؤال في مكان آخر!!!! طالباً إعطاءك فقط كود لتضعه وليس شرحاً فقط لأنك في ضيق من وقتك!!!

واعطيتك كود مع شرح في أبسط طريقة أعرفها

على كل حال هذا المنتدى مفتوح و نأمل ممن يعرف غير هذا الكود وغير هذه الطريقة البسيطة أن يفيدك أكثر مني

والسلام

هوا الصراحة الكود مازبط معايا طلعلي بعض الاخطاء وحاولت حلها لكني لم استطع لان الاخطاء كانت في التعريفات نفسها

ابو علاء

اخي أبو علاء بالتوفيق إن شاء الله

ودائماً انت على الرحب و السعة