بالنسبه لعمليه تبادل الملفات

جزء المستقبل

==================

انشئ مشروع جديد

اضف اداة Winsock

Option Explicit

Private Sub Form_Load()
'اعطاء اداة winsock منفذ لتعمل علية
Winsock1.LocalPort = 15000
'اعطاء امر لwinsock لانتظار الاتصال
Winsock1.Listen
End Sub


Private Sub Winsock1_ConnectionRequest(ByVal requestID As Long)
'عند وصول اتصال اغلاق winsock استعدادا لاستقبال الاتصال
Winsock1.Close
'قبول الاتصال
Winsock1.Accept requestID
'فتح ملف للكتابة علية
Open "اسم الملف" For Binary As #1
End Sub


Private Sub Winsock1_DataArrival(ByVal bytesTotal As Long)
Dim Data() As Byte
'استقبال البيانات الورادة الى winsock
Winsock1.GetData Data()
'وضع البيانات في الملف الذي سبق انشائة
Put #1, , Data()
End Sub


Private Sub Winsock1_Close()
'عند قطع الاتصال اغلاق الملف (عملية الارسال انتهت)
Close #1
End Sub

جزء المرسل

===================

انشئ مشروع جديد

اضف اداة Winsock

Option Explicit

Private Sub SendFile()
'امر الاتصال علي المستقبل
'"127.0.0.1" هو الرقم اي بي الافتراضي لجهاز الكمبيوتر
'Winsock1.Connect اي بي الجهاز الذي تريد الاتصال بة, رقم المنفذ
Winsock1.Connect "127.0.0.1", 15000
'التوقف حتى تمام الاتصال
Do Until Winsock1.State = sckConnected
    DoEvents
Loop

Dim Buffer() As Byte
'انشاء مصفوفة بحجم الملف
ReDim Buffer(FileLen("اسم الملف"))
'فتح الملف وتحميلة علي المصفوفة
Open "اسم الملف" For Binary As #1
    Get #1, , Buffer
Close #1
'ارسال المصفوفة الي المستقبل
Winsock1.SendData Buffer
End Sub
Private Sub Winsock1_SendComplete()
'بعد تمام الارسال اقطع الاتصال
Winsock1.Close
End Sub

مثال ممتاز Voodoo

اشكرك اخى voodo من كل قلبى