كيف نتحكم بحقل الوقت عن طريق ازرار التحكم كما هو موجود بساعة الوندوز

لتنفيذ ذلك ستحتاج الى تقسيم المربع الذى تعرض به الوقت الى 3 أجزاء

واحد للساعات و واحد للدقائق و واحد للثوانى

وعليكم السلام :)

أخي ابو يوسف ، طريقتك هي الامثل والاسهل ، لكن امر SelStart يلعب في رأسي ، وقد نستطيع عمل المطلوب عن طريقه في مربع واحد :) ، ايش رأيك :)

وياريتك تنظر في مشكلتي في المنتدى ، والتي شرحتها في الرابط:

/index.php/topic/292565-%D9%84%D9%85-%D8%A7%D8%B9%D8%AF-%D8%A7%D8%B3%D8%AA%D9%84%D9%85-%D8%A7%D9%8A-%D8%A7%D8%B4%D8%B9%D8%A7%D8%B1%D8%A7%D8%AA-%D8%B9%D9%84%D9%89-%D8%A7%D9%84%D8%A7%D9%8A%D9%85%D9%8A%D9%84-%D9%85%D9%86-%D8%A7%D9%84%D9%85%D9%86%D8%AA%D8%AF%D9%89/

شكرا

جعفر

نعم ، تم عمل الازم بمربع واحد ، عن طريق الامر SelStart :)

وهذا هو الكود:

Option Compare Database

'keep the value of what/where we clicked, in memory
Public Where_Clicked As String


Function Change_Time(N)

    Dim T, TT As Date
    
    'keep the values in memory, as the time might change meanwhile, so keeping it in memory keeps us safe :)
    '10:23:AM
    hh = Mid(Me.txta, 1, 2)
    hh2 = Mid(Me.txta, 1, 2)
    nn = Mid(Me.txta, 4, 2)
    AMPM = Mid(Me.txta, 7, 2)
    
    'lets convert the time in the Form, to a normal 24 hours time,
    'as the time displayed in the Form is NOT normal
    If AMPM = "PM" Then
        hh = Val(hh) + 12
    Else
        hh = Val(hh)
    End If
    
    'the normal time in 24 hours
    TT = TimeSerial(hh, Val(nn), 0)
    
    'based on where we clicked, we will adjust the values
    Select Case Where_Clicked
    
        Case "hh"

            'Hours
            'add the Up/Down 1 hour to our 24 hour time
            T = DateAdd("h", N, TT)
            'Disply it on the Form
            Me.txta = Format(T, "hh:") & Format(T, "nn:") & Format(T, "AM/PM")
            
        Case "nn"
            
            'Minutes
            'add the Up/Down 1 minute to our 24 hour time
            T = DateAdd("n", N, TT)
            'Disply it on the Form
            Me.txta = Format(T, "hh:") & Format(T, "nn:") & Format(T, "AM/PM")
            
        Case "AMPM"
            
            'exchange AM <> PM
            If AMPM = "AM" Then
                AMPM = "PM"
            Else
                AMPM = "AM"
            End If
            'Disply it on the Form
            Me.txta = hh2 & ":" & nn & ":" & AMPM
            
    End Select
    
        
End Function

Private Sub cmd_Down_Click()

    'call the Time adjustment Function,
    'telling it is a -1 adjustment
    Call Change_Time(-1)
End Sub

Private Sub cmd_up_Click()

    'call the Time adjustment Function,
    'telling it is a 1 adjustment
    Call Change_Time(1)
End Sub

Private Sub txta_Click()
   
    'where we clciked?
    'in order for us to find out if we clicked on the Hours or Minutes or AM/PM
    'for example, if out time is: 10:23:AM, then cursor location:
    '0 = befor the number 1
    '1 = after the number 1
    '2 = after the number 0
    '3 = after the hours :, but before the number 2
    '4 = after the number 2
    '5 = after the number 3
    '6 and above, its AM/PM
    
    'in order for us to use the Select Start .SelStart, we have to set focus to the field
    Me.txta.SetFocus
    
    'now based on the above table, we can tell if we clicked on the Hours or Minutes or the AM/PM
    Select Case Me.txta.SelStart
        
        Case 0, 1, 2
            'save the click location in a Global variable, Where_Clicked
            Where_Clicked = "hh"
            
        Case 3, 4, 5
            Where_Clicked = "nn"
        
        Case Else
            Where_Clicked = "AMPM"
        
    End Select
    
End Sub

Private Sub Form_Load()

    'Display the Time in a format that will NOT change when we click on it.
    'if we use Me.txta = Time() , or Me.txta = Now() , then taming it with Format(now(), "hh:nn:AM/PM")
    'although that will show us the time we need, but once we click in the field, the Time format changes :(
    '
    'so I arrived to format, which serves the user's purpose, and the programmers too :)
    Me.txta = Format(Time(), "hh:") & Format(Time(), "nn:") & Format(Time(), "AM/PM")
    
    'don't set the focus on the time
    Me.cmd_up.SetFocus
    
End Sub

جعفر

239.DATATIME_T.mdb.zip

الله يعطيك الف الف عافية اخي جعفر

هذا هو المطلوب

أشكرك على  تعاونك

تقبل تحياتي

فقط واجهة مشكلة واحدة اخي جعفر

عندما قمت بتحويل الحقل الى حقل منظم

وربطتة بالجدول وجعلته  حقل تاريخ / وقت

عند فتح النموذج تظهر رسالة خطأ لايمكن تخصيص قيمة لهذا الكائن