كيف اعرف تنسيق ملف الاكسس برمجيا

يا سلام عليكي يا أستاذتنا

تسلم يدك من كل سوء

هوه ده المطلوب بالفعل

بس ليه بيظهر لي الخطأ ده

بارك الله بك اخي الكريم : الشاذلي

يظهر هذا الخطأ 2110 عند فتح الملف  بنسخة الأكسيس 2007 او  2010  وتم اصلاح الخلل

اما مع اكسيس 2003 فلا يظهر اي خطأ

اعد تحميل الملف

بالتوفيق

فعلا أختى زهرة ، أنا بستخدم إصدار 2007 و الملف بتنسيق 2003 ، حملت الملف الجديد ولم يظهر لى أى خطأ

ربنا يبارك فيكي و يجعله لكي فى ميزان حسناتك

شاكر لكي تعبك معي

بارك الله بك اخي الكريم : الشاذلي

لقد عملت الملف على اكسيس 2003 ليقوم بتحميله جميع الأخوة الكرام في المنتدى لأنه سيعمل على جميع نسخ الأكسيس

بالتوفيق

كل الشكر و التقدير لكي أختي زهرة . 

بارك بك اختي ام عهود مثال جميل+

بالتأكيد المثال جميل

و لكنى لأول مرة أختلف مع استاذتنا أم عهود

فالكود يعتمد على امتداد الملف لتحديد تنسيقه و هذا لن يعطى نتائج صحيحه دائما

لأن امتداد الملف يمكن تغييره و بالتالى ستكون النتائج مختلفة رغم عدم تغير الملف

لذلك يجب الاعتماد على خصائص الملف و هذا غير صعب

الكود التالى يتيح ذلك

1- ضع هذا الكود فى وحدة نمطية

Public ACCESS_INFO As ACCESS_FILE_INFO
Private Type ACCESS_FILE_INFO
    AccessVersion As String
    AccessName As String
    FileFormat As String
    JetVersion As String
End Type

Public Sub GetFileInfo(dbname As String)
On Error GoTo Err_Handler
    
    Dim strReturn As String
    Dim db As dao.Database
    Dim MDE As Boolean
    
    ACCESS_INFO.AccessVersion = SysCmd(acSysCmdAccessVer)
    Select Case SysCmd(acSysCmdAccessVer)
    Case 9#    '1997
           ACCESS_INFO.AccessName = "MS ACCESS 1997"
    Case 10#   '2000
            ACCESS_INFO.AccessName = "MS ACCESS 2000"
    Case 11#   '2002 2003
            ACCESS_INFO.AccessName = "MS ACCESS 2003"
    Case 12#   '2007
            ACCESS_INFO.AccessName = "MS ACCESS 2007"
    Case 14#   '2010
            ACCESS_INFO.AccessName = "MS ACCESS 2010"
    Case Else
            ACCESS_INFO.AccessName = "UNKOWN MS ACCESS"
    End Select
    
        Set db = DBEngine.Workspaces(0).OpenDatabase(dbname)
        MDE = IsMDE(db)
        ACCESS_INFO.JetVersion = db.Version
    
    Select Case Int(Val(db.Version))
    'Access 97 file format is 3.0
    Case 3
        strReturn = "MD" & IIf(MDE, "E", "B") & "  MS ACCESS 1997"
    
    'Access 2000 or 2002/3 file format is 4.0
    Case 4
        'Examine the Project Storage version to distinguish 2000 from 2002/3.
        Select Case db.Properties("AccessVersion")
        Case "08.50"        '2000 format.
            strReturn = "MD" & IIf(MDE, "E", "B") & "  MS ACCESS 2000"
        Case "09.50"        '2002/3 fomat.
            strReturn = "MD" & IIf(MDE, "E", "B") & "  MS ACCESS 2003"
        End Select
            
    'Access 2007 (accdb) file format is 12.0
    Case 12
        strReturn = "ACCD" & IIf(MDE, "E", "B") & "  MS ACCESS 2007/10"
    'Access 2010 (accdb) file format is 14.0
    'Case 14
        'strReturn = "MS ACCESS 2010"
    End Select
       
    'Return value.
    If strReturn <> vbNullString Then
        ACCESS_INFO.FileFormat = strReturn
    End If

Exit_Handler:
    On Error Resume Next
        db.Close
        Set db = Nothing
    Exit Sub

Err_Handler:
    Select Case Err.Number
    Case 2482&, 3270&      'Object wasn't found (the Eval()). Property doesn't exist.
        Resume Next
    Case Else
        MsgBox Err.Number & vbCrLf & Err.Description
        Resume Exit_Handler
    End Select
End Sub

    Public Function IsMDE(ByVal dbname As dao.Database) As Boolean
        'Purpose: Retutn True if this is an MDE.
            On Error GoTo NotMDE
            If dbname.Properties("MDE") = "T" Then
                IsMDE = True
            Else
                IsMDE = False
            End If
                 
ExitHere:
           Set dbname = Nothing
            Exit Function
       
NotMDE:
            IsMDE = False
            Resume ExitHere
    End Function

2- لاستخدام الكود

GetFileInfo dbpath
Me.AccessVersion = ACCESS_INFO.AccessVersion
Me.AccessName= ACCESS_INFO.AccessName
Me.FileFormat = ACCESS_INFO.FileFormat
Me.JetVersion = ACCESS_INFO.JetVersion

أستاذنا أبو يوسف

أشكرك على المشاركة

لكن الكود رقم 2 يستخدم فين . وهل استخدمه على نفس تصميم المثال السابق .

إن تكرمت حضرتك ممكن ترفق مثال

مشكور مره أخرى

el-shazly كتب:

أستاذنا أبو يوسف

أشكرك على المشاركة

لكن الكود رقم 2 يستخدم فين . وهل استخدمه على نفس تصميم المثال السابق .

يمكنك أخى استدعائه فى أى مكان

و يمكنك تطبيقه على المثال الخاص بأم عهود

حاول أخى و ان واجهتك مشكلة فأنا معك

Abo_Yossof كتب:

يمكنك أخى استدعائه فى أى مكان

 

و يمكنك تطبيقه على المثال الخاص بأم عهود

 

حاول أخى و ان واجهتك مشكلة فأنا معك

بارك الله فيك أستاذنا أبو يوسف

جربت المثال و كله تمام

ربنا يزيدك من علمه