هل من طريقة لتشغيل معالج تصدير البيانات في حالة إخفاء الخلفية ؟

الظل الغامض كتب:

السلام عليكم ورحمة الله وبركاته ,,

صباح النصر قد لاح على أرض شامنا الحبيبة ,,

 

سؤال أحبتي : كيف يمكنني تشغيل معالج التصدير في حالة تم إخفاء خلفية الاكسس ؟

قد تستغربون من السؤال : سبب طرح السؤال هو أني أريد طريقة من خلالها أستطيع تصدير

نماذج ووحدات نمطية وجداول الى ملف اكسس آخر ؟ مع التاكيد على عدم ظهور خلفية الاكسس

 

اللهم أسعد وأفرح من ساعدنا وحل لنا الاشكال ,,

تفضل اخي الكريم

استخدم هذه الوظيفة العامة لتصدير جميع كائنات قاعدة البيانات الى القاعدة الخارجية

ضع هذه الكود في وحده نمطيه

Public Function zaExportAllobject2ExtDb(ExternalDb As String)
    On Error GoTo Error_Handler
    Dim qdf As QueryDef
    Dim tdf As TableDef
    Dim obj As AccessObject
 
    ' تصدير النماذج
    For Each obj In CurrentProject.AllForms
        DoCmd.TransferDatabase acExport, "Microsoft Access", ExternalDb, acForm, obj.Name, obj.Name, False
    Next obj
 
    ' تصدير الماكرو
    For Each obj In CurrentProject.AllMacros
        DoCmd.TransferDatabase acExport, "Microsoft Access", ExternalDb, acMacro, obj.Name, obj.Name, False
    Next obj
 
    ' تصدير الوحدات النمطية
    For Each obj In CurrentProject.AllModules
        DoCmd.TransferDatabase acExport, "Microsoft Access", ExternalDb, acModule, obj.Name, obj.Name, False
    Next obj
 
    ' تصدير الإستعلامات
    For Each qdf In CurrentDb.QueryDefs
        If Left(qdf.Name, 1) <> "~" Then
            DoCmd.TransferDatabase acExport, "Microsoft Access", ExternalDb, acQuery, qdf.Name, qdf.Name, False
        End If
    Next qdf
 
    ' تصدير التقارير
    For Each obj In CurrentProject.AllReports
        DoCmd.TransferDatabase acExport, "Microsoft Access", ExternalDb, acReport, obj.Name, obj.Name, False
    Next obj
 
    'تصدير الجداول
    For Each tdf In CurrentDb.TableDefs
        If Left(tdf.Name, 4) <> "MSys" Then
            DoCmd.TransferDatabase acExport, "Microsoft Access", ExternalDb, acTable, tdf.Name, tdf.Name, False
        End If
    Next tdf
 
Error_Handler_Exit:
    On Error Resume Next
    Set qdf = Nothing
    Set tdf = Nothing
    Set obj = Nothing
    Exit Function
 
Error_Handler:
    MsgBox " هناك خطأ في التصدير " & vbCrLf & vbCrLf & _
           " رقم الخطأ: " & Err.Number & vbCrLf & _
           " مصدر الخطأ : " & sModName & "/zaExportAllobject2ExtDb" & vbCrLf & _
           " وصف الخطأ : " & Err.Description, _
           vbCritical, "تنبيه"
    Resume Error_Handler_Exit
End Function

تم تنفيذ ما وضحته أستاذة أم عهود , لكن تورطنا في اكمال استدعاء الوظيفة 

إليكِ المرفق , بوركتِ وبوركت مساعيك وقُرت عينيك بصلاح بنيك

Zh511.rar

اخي الفاضل

ما هي المشكلة بالضبط !!!!!

ارجو التوضيح اكثر !!!!!

اتمنى في المرات القادمة من مشاركاتك ان تشرح بالتفصيل ما هي الصعوبات التي تواجهك حتى نستطيع مساعدتك بقدر استطاعتنا بأسهل الطرق بعيدا عن التعقيدات

لأنني لا احبذ مثل هذه التصرفات عندما يقوم اي شخص بوضع اي ملف بدون اي شروحات او اين تكمن المشكلة بالضبط .

بالتوفيق

أعتذر أستاذة أم عهود أعتقدت أني أوصلت المشكلة بالشكل المطلوب

وضعت الكود في الوحدة النمطية ولكن بقي كيف يتم تنفيذ التصدير ؟

لدي نموذج ووحدة نمطية وماكروا وجدول , كيف يتم تصديرها الى ملف اكسس آخر بعد أن قمنا بوضع الكود في الوحدة النمطية ؟

كيف يتم اختيار الملف بطريقة الاستعراض ومن ثَم الاختيار ؟

أتمنى أني أوصلت لك فكرة الاشكال , يارب 

والله يا أستاذة أستحق هذا الكلام واجزم أنه موجه لي وسعيد به في الحقيقة

لانه يحركنا قُدماً للتعلم , ولن يكون التعلم الا بعد الله من خلال معلم وأنتم نحسبكم خير معلم لهذا التخصص

بالتأكيد مررتِ بمرحلة الاسئلة والبحث عن حلول واحتجتِ مساعدة أحد ما كان له خبرة في هذا المجال

نحن نمر بهذه المرحلة كالاطفال كثيري الاسئلة والسبب حب المعرفة وحب التعلم والاستطلاع !

خُذيني بلطفك دوماً ,,

ستكونين سعيدة حينما ترين كم استفدت من أكوادك ومن شروحك

لعلي أطلعك فيما بعد على الفوائد وعلى النتائج ان شاء الله ,,

لك احترامي , ووافر دعائي ,,

لو سمح لي النظام بالتقييم لفعلت لكنه رفض لاني تعديت عدد تقييمات اليوم

بارك الله فيكـ اختنا أم عهود ونفعنا الله من علمكـ الذي لا ينضب

وكلمة شكر لصاحب الموضوع الاخ الظل الغامض ،،،

سبحان من علم بالقلم ،،، ما شاء الله اخي الكريم

تعابيرك راقت لي فأحببت أن اشكرك عليها

تحياتي

أستاذتنا الفاضلة أم عهود سؤال ؟ 

بعد التصدير هل فيه طريقة  لفتح الملف الذي تم تصدير الكائنات له وفتح نموذج محدد ؟

حتى مع وجود ماكروا بدء التشغيل لنموذج آخر ؟

الظل الغامض كتب:

أستاذتنا الفاضلة أم عهود سؤال ؟ 

بعد التصدير هل فيه طريقة  لفتح الملف الذي تم تصدير الكائنات له وفتح نموذج محدد ؟

حتى مع وجود ماكروا بدء التشغيل لنموذج آخر ؟

تفضل  اخي الكريم

بعد عملية تصدير كافة كائنات القاعدة الى قاعدة خارجية يمكننا ان نفتح اي كائن بها سواء نموذج او تقرير او استعلام او اي شيء بهذه الطريقة

zaExportAllobject2ExtDb-UP.rar

بالتوفيق

سلمت الأيادي والأنامل بارك الله فيك أستاذة أم عهود ورفع قدرك وأعلى شأنك وأصلح لك ذريتك 

حقيقة قد لاتفي حروف الشكر أدعها في ساعة مستجابة بحوله تعالى ,,

دمجت كود التصدير والفتح في زر واحد هل في هذا إشكال  مع أنه يعمل بكل سلاسة ,,

وضعت تقييم وكانت النتيجة !!

 لعلي أقيم في وقت آخر بمشيئة الله : 

بارك الله بك اخي الكريم

وجزاك الله كل خير

ودعوة صالحة بظهر الغيب افضل من مليون تقييم

بالنسبة لدمج الكودين معا فلا يوجد مشكله بها ابدا

ولهذا فضلت ان يكون كود التصدير منفصل عن كود فتح النموذج حتى تعرف الطريقه ويكون كود فتح النموذج ظاهرا أمامك

بالتوفيق

بارك الله فيك أستاذة أم عهود , لن ننساكم من الدعاء بمشيئة الله 

ارض مكة الطاهرة فيها دعوات مستجابات بحوله تعالى ,,

السلام عليكم ورحمة الله وبركاته 

حياك الله أستاذة أم عهود وكل عام والامة الاسلامية بخير 

بعد التصدير وبعد فتح البرنامج الذي صدرنا له هل يمكن اغلاق البرنامج الذي صدرنا منه اغلاقاً كاملاً ؟

استطعت ان اعمل له انهاء لكن لايخرج خروجاً كاملاً يبقى يعمل في الخلفية ؟

اخي الفاضل

وعليكم السلام ورحمة الله وبركاته

يكفي فقط ان تضع في نهاية كود فتح القاعدة الثانية الكود التالي

DoCmd.Quit

Private Sub CmdOpenExtForm_Click()
If IsNull(Me.txtPath) Then
MsgBox "  عذرا أخي الكريم..... لم تختار قاعدة البيانات المطلوبة  ", vbCritical, "تنبيه"
Exit Sub
Else
 
Dim appAccess As Access.Application
Dim ExtDB As String
ExtDB = Me.txtPath
Set appAccess = CreateObject("Access.Application")
appAccess.OpenCurrentDatabase ExtDB
appAccess.UserControl = True
appAccess.DoCmd.OpenForm "zx", acNormal
End If
DoCmd.Quit
End Sub

بارك الله فيك أستاذنا الفاضلة أم عهود لاحرمكِ الله الأجر والمثوبة