ارجو المساعده في حل هذه المشكله

السلام عليكم...

أفترض أنه يوجد Shape اسمه Shape1 داخل PictureBox اسمه Picture1.

1. لوضع مركز الـ Shape1 عند النقطة التي يتم النقر عليها داخل الـ Picture1 يكون الكود بسيطاً: سطر واحد كالتالي في الحدث MouseDown لـ Picture1:

Private Sub Picture1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Button = vbLeftButton Then
        Shape1.Move X - Shape1.Width \ 2, Y - Shape1.Height \ 2
    End If
End Sub

2. أما لإمساك الـ Shape1 بالفأرة و تحريكه أينما تحرك مؤشر الفأرة فإن الكود أطول قليلاً لأن الـ Shape في Visual Basic 6 لا يستجيب لأية أحداث (ليس له إجراءات). و الكود كالتالي:

' في قسم التصريحات العام. متغيرات لحفظ البيانات
Private StartX As Long
Private StartY As Long
Private StartLeft As Long
Private StartTop As Long
Private Dragging As Boolean

Private Sub Form_Load()
    Dragging = False
    
    ' يمكن ضبط هذه الخصائص أثناء التصميم و حذف هذين السطرين
    Picture1.ScaleMode = vbPixels
    Picture2.ScaleMode = vbPixels
End Sub

' عند الضغط على المربع بالزر الأيسر. نحتفظ ببيانات موقع النقر و نؤشر لبداية عملية السحب
Private Sub Picture1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Button = vbLeftButton Then
        If (X >= Shape1.Left) And (X <= (Shape1.Left + Shape1.Width)) _
                And (Y >= Shape1.Top) And (Y <= (Shape1.Top + Shape1.Height)) Then
            StartX = X
            StartY = Y
            StartLeft = Shape1.Left
            StartTop = Shape1.Top
            Dragging = True
        End If
    End If
End Sub

' عند تحريك المؤشر مع الضعط نحرك المربع حسب حركة المؤشر
Private Sub Picture1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If (Button = vbLeftButton) And Dragging Then
        Shape1.Left = StartLeft + X - StartX
        Shape1.Top = StartTop + Y - StartY
    End If
End Sub

' عند إفلات الزر الأيسر نلغي إشارة السحب
Private Sub Picture1_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
    Dragging = False
End Sub

في المرفقات مشروع لتوضيح الطريقتين.

MoveShapes.rar

نرجو الاستفادة و السلام.