البحث في قواعد البيانات

السلام عليكم و رحمة الله و بركاته...

اقتباس

وانا اسفة لكتر الأسالة بس اعدكم يكون اخر طلب

:unsure:

لا داعي للأسف و لا داعي لأن تكون آخر مرة، فكلنا هنا لنتعلم، و لنعلم قدر المستطاع بما علمنا الله، و من حق كل مشترك أن يسأل، و من واجب الآخرين أن يجيبوه بما يعرفون.

حاولت تنزيل المشروع لكن الرابط إلى الموقع المذكور يعطي رسالة بأن الملف غير موجود. الرجاء التأكد من الرابط، أو ربما يكون من الأفضل إرفاق المشروع مع المشاركة (تحميل ضمن هذا المنتدى).

أرجو لك التوفيق و السلام.

السلام عليكم...

مشروعك يحتوي على مكونات من غير مكونات VB و هي غير متوفرة لدي.

على أية حال رأيت شاشة البحث و قاعدة البيانات، و أريد فقط التوضيحات التالية في شاشة البحث:

1. عند اختيار "بحث في الفهرس": في أي جدول و في أي حقل يجب البحث؟

2. عند اختيار "بحث داخل الموضوعات": في أي جدول و في أي حقل يجب البحث؟

3. ما هي نتائج البحث التي يجب عرضها في قائمة نتيجة البحث؟ مثلاً عناوين المواضيع ذات العلاقة أم ماذا؟.

نرجو التوضيح و السلام.

شكرا اخى لمساعدتى وجزاك الله كل خير

عن البحث فى الفهرس يتم البحث فى treeview اسم الجدول Functions الحقل FunctionName

عند بحث داخل الموضوعات يتم البحث فى textbox اسم الجدول Functions الحقل Description

النتيجة تعرض فى list view يعنى مثلا لو بحثت بحرف يعرضلى الجملة الى بيها الحرف وعند الضغط عليها يتم تحديدها فى مكنها سواء فى treeview او ltextbox

ودى صورة ياخى للمطلوب

:sad:

انا اسفة جدا لتعبك معايا

السلام عليكم...

بما أنه لا يمكنني حفظ مشروعك كما هو لديك بسبب وجود المكونات الخارجية فسوف أقدم لك بعض الخطوات و الكود الكامل لنافذة البحث:

1. في الـ Module قومي بتعريف الثابت التالي (انسخيه من هنا):

Public Const MSG_ARABIC = vbMsgBoxRight Or vbMsgBoxRtlReading

2. في النافذة Form2 اضبطي الخاصية HideSelection لكل من الـ TreeView1 و الـ Text1 على False

3. في النافذة Form2 ضعي تعريف الإجراء التالي:

Public Sub UpdateDescription(ByVal Node As MSComctlLib.Node)
    TreeView1_NodeClick Node
End Sub

* ضعي التعريف السابق في بداية الكود، و لكن بعد السطرين:

Dim db As ADODB.Connection
Dim rs As ADODB.Recordset

4. في نافذة البحث (frmserch) امسحي أي كود لديك ثم انسخي الكود التالي و ألصقيه:

Option Explicit

Private SearchTxt As String

Private Sub ChCaption_Click()
    If List1.ListCount > 0 Then
        List1.Clear
        Frame3.Caption = " نتيجة البحث... "
    End If
End Sub

Private Sub ChCode_Click()
    If List1.ListCount > 0 Then
        List1.Clear
        Frame3.Caption = " نتيجة البحث... "
    End If
End Sub

Private Sub Combo1_Change()
    If List1.ListCount > 0 Then
        List1.Clear
        Frame3.Caption = " نتيجة البحث... "
    End If
End Sub

Private Sub Command1_Click()
    Dim SQL As String
    Dim db As ADODB.Connection
    Dim rs As ADODB.Recordset
    Dim ACount As Long

    SearchTxt = Trim$(Combo1.Text)
    If SearchTxt = "" Then
        MsgBox "الرجاء إدخال نص البحث!", vbCritical Or MSG_ARABIC, "بحث"
        Combo1.SetFocus
        Exit Sub
    End If

    If (ChCaption.Value = vbUnchecked) And (ChCode.Value = vbUnchecked) Then
        MsgBox "يجب تحديد مكان واحد على الأقل للبحث!", vbCritical Or MSG_ARABIC, "بحث"
        ChCaption.SetFocus
        Exit Sub
    End If

    SQL = "SELECT ID, FunctionName FROM Functions WHERE "
    If (ChCaption.Value = vbChecked) And (ChCode.Value = vbChecked) Then
        SQL = SQL & "(FunctionName LIKE '%" & SearchTxt & "%') OR (Description LIKE '%" & SearchTxt & "%')"
    ElseIf ChCaption.Value = vbChecked Then
        SQL = SQL & "(FunctionName LIKE '%" & SearchTxt & "%')"
    Else    ' ChCode.Value = vbChecked
        SQL = SQL & "(Description LIKE '%" & SearchTxt & "%')"
    End If

    List1.Clear

    Set db = New ADODB.Connection
    Set rs = New ADODB.Recordset
    db.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & App.Path + "\z.mdb"
    rs.Open SQL, db, adOpenDynamic, adLockOptimistic
    ACount = 0
    Do While Not rs.EOF
        List1.AddItem rs("FunctionName")
        List1.ItemData(List1.NewIndex) = rs("ID")
        ACount = ACount + 1
        rs.MoveNext
        DoEvents
    Loop
    rs.Close
    db.Close
    Set rs = Nothing
    Set db = Nothing

    Frame3.Caption = " نتيجة البحث: " & CStr(ACount) & " عنصر"
End Sub

Private Sub Form_Load()
    SearchTxt = ""
End Sub

Private Sub List1_Click()
    Dim AKey As String
    Dim APos As Long

    If (List1.ListCount <> 0) And (List1.ListIndex <> -1) Then
        AKey = "F" & CStr(List1.ItemData(List1.ListIndex))
        Form2.TreeView1.Nodes(AKey).Selected = True
        'Form2.TreeView1.Nodes(AKey).EnsureVisible
        Form2.UpdateDescription Form2.TreeView1.Nodes(AKey)

        If (SearchTxt <> "") And (ChCode.Value = vbChecked) Then
            APos = InStr(Form2.Text1.Text, SearchTxt)
            If APos <> 0 Then
                Form2.Text1.SelStart = APos - 1
                Form2.Text1.SelLength = Len(SearchTxt)
            End If
        End If
    End If
End Sub

Private Sub XPButton2_Click()
    Unload Me
End Sub

5. في أمر القائمة "بحث في المواعيد" في النافذة الرئيسية اكتبي الكود التالي:

Private Sub shrch1_Click()
    Form2.Show
    frmserch.Show vbModal
End Sub

6. شغلي البرنامج.

نرجو الاستفادة و السلام.

اسال الله العظيم رب العرش العظيم ان يجزيك خير على مساعدتى

احسنت ياخى بارك الله فيك