هل الفي بي يملك هذه الخاصية

أخى أعتقد أن هذا بسهوله عن طريق الحدث MouseMove

اها نعم ..ممكن MouseMoveاو ربما ال mousEnter

ولكن ما هو الكود الذي سوف يقوم بالعملية .

كيف ممكن ان نكتبة !!!

تطبيقا على ال button

 Private Sub Button1_MouseHover(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.MouseHover
        Me.Button1.BackColor = Color.DeepPink
    End Sub

    Private Sub Button1_MouseLeave(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.MouseLeave
        Me.Button1.BackColor = Color.Transparent
    End Sub

كل التحية لك اخي الكريم ,,

نفذتو وزبط معاي ,,,

بس السؤال ,, هل ممكن ان احدد الون اللي بظهر في ,, "ارجو ان لا تكون اسألتي كثيرة ومزعجة".

وشكلو ع الpicture ما بزبط ,

جربت احط mouseHoevrما زبط ..

نعم أخى عن طريق ال Intellisense autocompletion

بارك الله فيك اخي الكريم ,اعرفت قبل ما تقول يعني جربتها

اذا بنفعش للصور

احط bouuon واختار خلفية الها تكون صورة اللي بدي اياها ,, فكرك ممكن يزبط انا ما جربت ,, بس ممكن ينفع , والمشكلة انو لو في صور ع شكل دائرة مش شكل مربع او مستطيل

ما زبط للأسف بضوي ال boutton كأنو صار الصورة جزء من ال boutton وهو ضوا بس الصورة ضلت متل ما هي

السلام عليكم ورحمة الله تعالى وبركاته، قمت في السابق ببناء User Control مشتق من فئة button يستجيب لهذا التأثير، بل له خصائص أخرى:

* عند التأشير عليه تظهر صورة محددة في خاصية ImageHover

* عند النقر عليه تظهر صورة محددة في خاصية ImageDown

* يمكن أن يعمل مثل CheckBox بجعل خاصية Toggle=true ومن ثم التعامل مع خاصية Checked وفي هذه الحالة ImageDown تعمل كصورة للحالة True و ImageNormal تعمل كصورة للحالة False

* عند تغيير Chacked يقوم برفع حدث CheckedChanged

هذه شفرة UserControl

designer

<Global.Microsoft.VisualBasic.CompilerServices.DesignerGenerated()> _
Partial Class ButtonHover
    Inherits System.Windows.Forms.Button

End Class

Code

Public Class ButtonHover
    Private _HoverImage As Image
    Private _DownImage As Image
    Private _NormalImage As Image
    Private out As Boolean = True
    Private _Checked As Boolean
    Private _Toggle As Boolean

    Public Property Toggle() As Boolean
        Get
            Return _Toggle
        End Get
        Set(ByVal value As Boolean)
            _Toggle = value
        End Set
    End Property

    Public Event CheckedChanged(ByVal sender As Object, ByVal e As EventArgs)
    Public Property Checked() As Boolean
        Get
            Return _Checked
        End Get
        Set(ByVal value As Boolean)
            _Checked = value
            RaiseEvent CheckedChanged(Me, New EventArgs())
        End Set
    End Property

    Public Property BackGroundHoverImage() As Image
        Get
            Return _HoverImage
        End Get
        Set(ByVal value As Image)
            _HoverImage = value
        End Set
    End Property

    Public Property BackGroundDownImage() As Image
        Get
            Return _DownImage
        End Get
        Set(ByVal value As Image)
            _DownImage = value
        End Set
    End Property


    Public Property BackGroundNormalImage() As Image
        Get
            Return _NormalImage
        End Get
        Set(ByVal value As Image)
            _NormalImage = value
        End Set
    End Property

    Private Sub ButtonHover_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Click
        If Toggle Then Checked = (Not Checked)
    End Sub



    Private Sub ButtonHover_MouseDown(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles Me.MouseDown
        If _DownImage IsNot Nothing Then Me.BackgroundImage = _DownImage
    End Sub
    Private Sub HoverButton_MouseEnter(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.MouseEnter

        If _HoverImage IsNot Nothing And Not Checked Then
            Me.BackgroundImage = _HoverImage
        Else
            Me.BackgroundImage = _DownImage
        End If

        out = False

    End Sub

    Private Sub HoverButton_MouseLeave(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.MouseLeave
        out = True
        If Toggle And _Checked Then
            Me.BackgroundImage = _DownImage
        Else
            Me.BackgroundImage = _NormalImage
        End If
    End Sub


    Private Sub ButtonHover_MouseUp(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles Me.MouseUp
        If Checked Then
            Me.BackgroundImage = _DownImage
        Else
            If out Then
                Me.BackgroundImage = _NormalImage
            Else
                Me.BackgroundImage = _HoverImage
            End If
        End If
    End Sub

    Sub Checked_Changed() Handles Me.CheckedChanged
        Try
            If _Checked Then
                Me.BackgroundImage = _DownImage
            Else
                Me.BackgroundImage = _NormalImage
            End If
        Catch ex As Exception

        End Try
    End Sub
End Class