سؤال فى عرض الصور تلقائيا

الكود التالي يفترض وجود:

* قائمة محركات أقراص: Drive Combo باسم Drive1

* قائمة مجلدات: Directory ListBox باسم Dir1

* قائمة ملفات: File ListBox باسم File1

* مؤقت: Timer باسم Timer1

* مربع صور: Image باسم Image1

Private ImgIndex As Long

Private Function AddBackslash(ByVal APath As String) As String
    If Right$(APath, 1) = "\" Then
        AddBackslash = APath
    Else
        AddBackslash = APath & "\"
    End If
End Function

Private Sub Dir1_Change()
    File1.Path = Dir1.Path
End Sub

Private Sub Drive1_Change()
    Dir1.Path = Drive1.Drive
End Sub

Private Sub File1_PathChange()
    Timer1.Enabled = False
    Image1.Picture = LoadPicture
    ImgIndex = 0
    If File1.ListCount <> 0 Then
        Image1.Picture = LoadPicture(AddBackslash(File1.Path) & File1.List(0))
        Timer1.Enabled = True
    End If
End Sub

Private Sub Form_Load()
    Timer1.Enabled = False
    Timer1.Interval = 1000
    File1.Pattern = "*.bmp;*.jpg;*.gif"

    ImgIndex = 0
End Sub

Private Sub Timer1_Timer()
    On Error GoTo Timer1_Timer_Err

    If File1.ListCount = 0 Then
        Timer1.Enabled = False
    Else
        ImgIndex = (ImgIndex + 1) Mod File1.ListCount
        Image1.Picture = LoadPicture(AddBackslash(File1.Path) & File1.List(ImgIndex))
    End If

    Exit Sub
Timer1_Timer_Err:
    Image1.Picture = LoadPicture
End Sub

الأسطر الثلاثة الأولى في الحدث Form_Load يمكن حذفها حيث يمكن ضبط الخاصيتين Enabled و Interval للـ Timer1 و الخاصية Pattern للـ File1 من نافذة الخصائص أثناء التصميم.

نرجو الاستفادة و السلام.