كيف يمكنني تحديد اكثر من خيار لمربع نص

للرفع لانه مهم .. ومنتظر جواب اخواني الأعضاء ^^

السلام عليكــم ورحمـة الله وبركاتــة

اعتقد ان مرفقك قد سقط منه هذا النموذج بالتحديد

وعليكم السلام ورحمة الله وبركاته ...

انا لدي مجموعة من الصفوف في مربع نص وعند التأشير على احد هذه الصفوف يتغير المحتوى للنموذج الفرعي الموجود في نفس النموذج الرئيسي ...

انا وضعت امر طباعة تقرير لهذه البيانات التي تظهر في النموذج الفرعي ، ولكن المشكلة تكمن في اني اذا اردت طباعة جميع هذه الصفوف ...

فهل من طريقة لعمل امر اختيار الكل ( لكل الخيارات في مربع النص ) .. او اختيار فئة معينة ( مجتمعة في اسم مشترك ) .....؟

بســم الله الـرحمــن الرحيــم

يا أخي الفاضل...

أرجو مراجعة مرفقك فليس بداخله النموذج الذي تتحدث عنه !!

السلام عليكم

بارك الله بك استاذ ايهاب اعتقد انه يقصد النموذج Class

اخي الكريم هناك طرق كثيرة لذلك هذه واحدة منها ارجو ان يكون هو المطلوب

الاكواد المستخدمة في التعديل هي من صناعة هذا المنتدى الجميل جزاهم الله كل خير.

SeGL_up1.rar

اخوي ايهاب ...

عند فتح النموذج استمر في الضغط على مفتاح shift

اخي سمير ...

بارك الله فيك على المحاولة ولكن لا اقصد هذا الأمر ...

انا اقصط الصفوف لنفرض اني اريد طباعة الصف الأول والثاني والثالث جميعهـا ... في زر واحد ....

فما بالك لو لدي اكثر من 30 صف .. فاالعملية متعبة في الضغط على صف تلو الصف ...

انا اريد طريقة لطباعة الصفوف كلهـا بأمر واااحد ....

تفضل اخي الكريم

ملفك بعد التعديل بناء على طلبك

قم بالضغط على زر الأمر " اختيار صف معين " ليتم اختيار اي صف تريد معاينته او طباعته للتقرير

لإختيار الكل اعد الضغط على زر الأمر " اختيار الكل ليتم اختيار جميع الصفوف ليتم إظهارها في التقرير

راجع آخر ملف للتعديل

za_SeGL_Last.rar

اختي الكريمة .. بارك الله فيك على المحاولة ...

عندما كنت اطبع الصفوف كنت اطبع كل صف لوحده ... وذلك بالتأشير على كل صف تلو الآخر ...

واردت امر لطباعة جميع الصفوف في زر واحد ( بشرط ان يظهر لي كل صف في صفحة مختلفة ) ...

لكن الذي كان منكي من الرد ، عبارة عن طباعة جميع الصفوف في ورقة واحدة .... وهذا مالا اريده .؟

للرفع ...

اقتباس

واردت امر لطباعة جميع الصفوف في زر واحد ( بشرط ان يظهر لي كل صف في صفحة مختلفة ) ...

اقتباس

السؤال : كيف يمكنني تحديد اكثر من خيار واحد من مربع النص ...

تفضل اخي الكريم

تستطيع اختيار اي صف وطباعتة بشكل مستقل في ورقة مستقله عن الصف الآخر

ايضا تستطع اختيار كل الصفوف عن طريق زر الأمر وسيتم طباعة كل صف لوحده في ورقة مستقله

آخر تعديل للملف

za_SeGL_Last.rar

طيب اختي الكريم ...

ما هي الخطوات اللي اضفتيها على برنامجي لعمل هذا الزر ... لاني تلخبطت شويه ^^

انا ادري اني تعبتك وياي ، وجزاك الله خير الجزاء ، ورزقك الذرية الصالحة التي تعينك على طاعة الله ...

اريد شرح الأضافات اللي عملتيهـا ...لانك غيرتي اسامي وعدلتي اشياء بالقاعدة ...؟

التغييرات التي تمت على قاعدة البيانات

الجداول : informations و Class

تم تغيير نوع الحقل Class من حقل نصي الى حقل رقمي فأصبحت حقول الصفوف هي 1 و 2 و 3 بدلا من 1/1 و 2/2 و 3/3

الإستعلامات : qryALL

تم اضافة الإستعلام qryALL مبني على الجدول informations لغرض استخدامه للتقرير

التقارير :

تم تعديل اسم التقدير من طباعة Informations الى ReportInformations

تم اضافة حقل نصي في رأس التقرير ووضعت به العبارة التالية ( Report.OpenArgs ) لغرض استخدامها مع كود فتح التقرير كمعيار للصفوف اثناء فتح التقرير

تم نقل جميع مربعات النص والتسميات من رأس التقرير الى رأس الصفحة لغرض اظهار اسم الصف مع كل صفحه لوحدها عند اختيار الصفوف

تم اضافة عامل الفرز والتجميع لكل صفحة على حده بإضافة المقطع رأس الصفحة Class

الوحدات النمطية

تم اضافة وحدة نمطية بإسم Module1 لمعالجة اخطاء البرنامج اثناء التنفيذ

النماذج ( Class )

تم اضافة زر الأمر CmdSelectALL الى النموذج Class وربطه بالقائمة List24

تم تعديل اسم القائمة من قائمة 24 الى List24

تم اضافة الكود التالي لزر الأمر

Private Sub cmdSelectAll_Click()
On Error Resume Next
Dim intCounter As Integer

	If CmdSelectALL.Caption = "إختيار صف معين" Then
	   Call SelectAll(Forms!Class!List24)

		For intCounter = 0 To List24.ListCount
			List24.Selected(intCounter) = True
	   Next intCounter
		Me.CmdSelectALL.Caption = "إختيار الكل"
	Else

	  Call ClearList(Forms!Class!List24)
	   Call List24_AfterUpdate
		For intCounter = 0 To List24.ListCount
			List24.Selected(intCounter) = False
		Next intCounter
		Me.CmdSelectALL.Caption = "إختيار صف معين"
	End If
End Sub

تم اضافة الوظيفة التالية SelectAll لإستخدامها في اختيار كل صفوف مربع القائمة List24

Public Function SelectAll(lst As ListBox) As Boolean
On Error GoTo Err_Handler
	Dim lngRow As Long

	If lst.MultiSelect = 1 Then

		For lngRow = 0 To lst.ListCount - 1
			lst.Selected(lngRow) = True
		Next
	   lst.MultiSelect = 1
		SelectAll = True

	End If

Exit_Handler:
	Exit Function

Err_Handler:
	Call LogError(Err.Number, Err.Description, "SelectAll()")
	Resume Exit_Handler
End Function

تم اضافة الوظيفة التالية ClearList لإستخدامها في إزالة اختيار كل صفوف مربع القائمة List24 لتعود القائمة الى الإختيار الفردي كل صف لوحده

Function ClearList(lst As ListBox) As Boolean
On Error GoTo Err_ClearList
	Dim varItem As Variant

	If lst.MultiSelect = 0 Then
		lst = Null
	Else
		For Each varItem In lst.ItemsSelected
			lst.Selected(varItem) = False
		Next
   lst.MultiSelect = 0
	End If

	ClearList = True

Exit_ClearList:
	Exit Function

Err_ClearList:
	Call LogError(Err.Number, Err.Description, "ClearList()")
	Resume Exit_ClearList
End Function

تم تعديل كود مشاهدة التقرير cmdPreview ليصبح بهذا الشكل

Private Sub cmdPreview_Click()
On Error GoTo Err_Handler
	Dim varItem As Variant
	Dim strWhere As String
	Dim strDescrip As String
	Dim lngLen As Long
	Dim strDelim As String
	Dim strDoc As String

	strDoc = "ReportInformations"
	With Me.List24
		For Each varItem In .ItemsSelected
			If Not IsNull(varItem) Then
				strWhere = strWhere & strDelim & .ItemData(varItem) & strDelim & ","
				strDescrip = strDescrip & """" & .Column(1, varItem) & """, "
			End If
		Next
	End With

	lngLen = Len(strWhere) - 1
	If lngLen > 0 Then
		strWhere = "[class] IN (" & Left$(strWhere, lngLen) & ")"
		lngLen = Len(strDescrip) - 2
		If lngLen > 0 Then
			strDescrip = "Class: " & Left$(strDescrip, lngLen)
		End If
	End If

	If CurrentProject.AllReports(strDoc).IsLoaded Then
		DoCmd.Close acReport, strDoc
	End If

	DoCmd.OpenReport strDoc, acViewPreview, WhereCondition:=strWhere, OpenArgs:=strDescrip

Exit_Handler:
	Exit Sub

Err_Handler:
	If Err.Number <> 2501 Then
		MsgBox "Error " & Err.Number & " - " & Err.Description, , "cmdPreview_Click"
	End If
	Resume Exit_Handler
End Sub