[ تمت الإجابة ]إخفاء الأيقونة من شريط العنوان

لم أجرب بعد، الفكرة التي تطوف برأسي هي hook على الـ window ومن ثم التقاط WM_SETICON ومعالجتها.

لا انسى تلك الفكرة السخيفة .. نسيت أننا نتعامل مع برنامجنا وليس برنامج آخر فلماذا hook؟ :blush:

Private Declare Function ShowWindow Lib "user32.dll" (ByVal hwnd As Long, ByVal nCmdShow As Long) As Long
Private Declare Function SetWindowLong Lib "user32.dll" Alias _
	 "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, _
	 ByVal dwNewLong As Long) As Long
Private Declare Function GetWindowLong Lib "user32.dll" Alias _
	 "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Integer, ByVal lParam As Long) As Long

Private Const WS_VISIBLE As Long = &H10000000
Private Const WS_EX_DLGMODALFRAME As Long = &H1&
Private Const GWL_STYLE As Long = -16
Private Const GWL_EXSTYLE As Long = -20
Private Const SW_SHOW As Long = 5
Private Const ICON_BIG = 1&
Private Const WM_SETICON = &H80

Private Sub Form_Activate()
Dim Style As Long
Dim exStyle As Long
	SendMessage Me.hwnd, WM_SETICON, ICON_BIG, 0
	Style = GetWindowLong(Me.hwnd, GWL_STYLE)
	Style = Style Xor WS_VISIBLE
	Style = SetWindowLong(Me.hwnd, GWL_STYLE, Style)
	exStyle = GetWindowLong(Me.hwnd, GWL_EXSTYLE)
	exStyle = exStyle Or WS_EX_DLGMODALFRAME
	exStyle = SetWindowLong(Me.hwnd, GWL_EXSTYLE, exStyle)
	ShowWindow Me.hwnd, SW_SHOW
End Sub

تأخرت فقد كانت لا تعمل وبقيت حوالي ساعة أنظر في الأمر ثم تذكرت أنه طالما هناك إمكانية لظهور البرنامج في الـ TaskBar فستظهر الأيقونة الافتراضية مهما حاولت أن أقوم بفعله. لذلك خطوات العمل باختصار هي التالية:

1. تقوم باستخدام SendMessage لإزالة الأيقونة الخاصة بالبرنامج وكأنه لا يستخدم أيقونة أبداً، في هذه الحالة النظام يقوم تلقائياً بوضع أقرب أيقونة افتراضية للنافذة.

2. تقوم بإلغاء ظهور البرنامج في الـ TaskBar فتختفي الأيقونة الأساسية للبرنامج.

3. تقوم بإعطاء البرنامج صفة Dialog Modal Frame فتختفي الأيقونة تماماً.

وهو المطلوب :)