كيفية اظهار واخفاء Taskbar عند تشغيل البرنامج

السلام عليكم...

الكود التالي يعمل على إخفاء و إظهار الـ TaskBar:

Private Const SW_HIDE = 0
Private Const SW_SHOW = 5

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function ShowWindow Lib "user32" (ByVal hwnd As Long, ByVal nCmdShow As Long) As Long

Private Sub SetWinTaskBarVisible(tbVisible As Boolean)
	Dim hTaskBar As Long

	hTaskBar = FindWindow("Shell_TrayWnd", vbNullString)
	If tbVisible Then
		ShowWindow hTaskBar, SW_SHOW
	Else
		ShowWindow hTaskBar, SW_HIDE
	End If
End Sub

Private Sub Form_Load()
	SetWinTaskBarVisible False
End Sub

Private Sub Form_Unload(Cancel As Integer)
	SetWinTaskBarVisible True
End Sub

نرجو الاستفادة والسلام.

جميل جدا ياخ najy_zl

وجزاك الله كل خير ولكن هناك جزئية بسيطة انا اريد الفورمة تملا الشاشة كلها بمعني مكان taskbar ميكنش خالي يكون مملؤء بالفورمة حولت اعملهابخاصية width للفورمة ولم تنج ياريت تتوصل الي هذة النقطة

لازم تسوي الـ WindowState = vbMaximize

يعني تكبير للفورم ,, وبعدين تسوي البوردر أو الحدود = 0 = Border

وبالأخير تسوي كود اللي هو فوق الجميع ,,

أو إسمها TopMost أو In Top Of All

http://up.x333x.com/download.php?filename=e5132fd3b2.rar

هذا مثال فيه فورمـ و2 كوماند بوتون ,,, المهمـ ,,,

شغل المشروع ,, جرب Set me on top <<< رح تصير معاك الواجهة ملء الشاشة ,, + فوق الجميع ,, وعندك اللي تحت عشان الإغلاق ,,

بالنسبة لإزالة التوبموست ,, إستدعي الدالة بس بقيمة 0 بدال -1 ,,

تقبل مروري , ,

انا فعلا عملت الطريقة دي علي فورمة عادية وتنفعت بس انا عايز اعملها علي فورمة من نوع MDI انا جربتها بس مفهاش خاصية border يارت تساعدني فيها

السلام عليكم...

الكود التالي يعمل على تكبير نافذة الـ MDI بحجم الشاشة و وضعها في المقدمة مع تعطيل زر التكبير (Maximize) لأنه إذا لم يتم تعطيل هذا الزر فإن النافذة عند تكبيرها ستترك مكان شريط المهام (TaskBar) فارغاً.

اترك الخاصية WindowState مضبوطة على Normal.

إذا أردت منع المستخدم من تحريك النافذة فاضبط الخاصية Movable على False.

أثناء التشغيل ستحتوي قائمة النظام (System Menu) الخاصة بالنافذة على الأمر "تكبير" لكن لا أهمية له لأنه سيؤدي إلى تغيير بسيط جداً في حجم النافذة. و مع ذلك يمكن حذف ذلك الأمر من قائمة النظام، لكنني لم أضعه هنا حتى لا يكون الكود طويلاً.

Private Const WS_MAXIMIZEBOX = &H10000
Private Const GWL_STYLE = (-16)

Private Const HWND_TOPMOST = -1
Private Const SWP_NOACTIVATE = &H10
Private Const SWP_SHOWWINDOW = &H40

Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Sub SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long)

Private Sub MDIForm_Load()
	Dim OldLong As Long

	' حذف زر التكبير:
	OldLong = GetWindowLong(Me.hwnd, GWL_STYLE)
	SetWindowLong Me.hwnd, GWL_STYLE, OldLong And (Not WS_MAXIMIZEBOX)
End Sub

Private Sub MDIForm_Activate()
	' وضع النافذة في المقدمة:
	SetWindowPos Me.hwnd, HWND_TOPMOST, 0, 0, Screen.Width / Screen.TwipsPerPixelX, Screen.Height / Screen.TwipsPerPixelY, SWP_NOACTIVATE Or SWP_SHOWWINDOW
End Sub

نرجو الاستفادة و السلام.