السلام عليكم .. كيف أريد أن أحدد وأضيف أكثر من ملف في ال Listview

مين يعرف الحل

انتظر الحل من بعد إذنكم

قد يفيدك هذا الرابط

/index.php?showtopic=81990

لو سمحتو ماهي الأكواد اللازمة لإضافتها لزر البرنامج

لكي أستطيع من خلاله تحديد أكثر من ملف

انا جربت الكود اللي وضعه الأخ DreamNet بس ما زبط معي

لو سمحتوا أريد لما أضغط على زر أختيار ملفات أن احدد أكثر من ملف

هنا بعد ما ضغط على زر أختيار ملفات سوف يفتح الديالوج بس المشكلة انو يحدد ملف واحد فقط

وانا اريد احدد اكثر من ملف واضيفه للـ ListView

أنتظر الحل

السلام عليكم...

لكي يتمكن المستخدم من اختيار عدة ملفات يجب إضافة الثابت cdlOFNAllowMultiselect إلى الخاصية Flags التابعة للمكون CommonDialog، كما هو مبين في الكود.

النقطة التي يجب ملاحظتها هنا هي أنه عند اختيار ملف واحد فإن الخاصية FileName تحتوي على المسار (Path) و اسم الملف (File name)، أما عند اختيار عدة ملفات فإن الخاصية FileName تحتوي أولاً على المسار (Path) متبوعاً بالحرف NULL (أو Chr(0))، ثم أسماء الملفات مفصولة أيضاً بالحرف NULL، و لذلك ففي هذه الحالة نحتاج إلى تفكيك نص الخاصية FileName للحصول على المسار و أسماء الملفات، كما هو مبين في الكود أيضاً.

Private Sub Form_Load()
	' ضبط الخاصية Flags:
	CommonDialog1.Flags = cdlOFNFileMustExist Or cdlOFNHideReadOnly _
						  Or cdlOFNAllowMultiselect Or cdlOFNExplorer
End Sub

Private Sub Command1_Click()
	Dim SelectedFiles As String
	Dim NCPos As Long
	Dim ThePath As String
	Dim TheFile As String
	Dim AItem As ListItem

	On Error GoTo Command1_Click_Error

	CommonDialog1.FileName = ""
	CommonDialog1.ShowOpen
	SelectedFiles = CommonDialog1.FileName
	' نبحث عن الحرف NULL:
	NCPos = InStr(SelectedFiles, vbNullChar)
	If NCPos = 0 Then
		' لا يوجد. إذن المستخدم اختار ملفاً واحداً
		' نبحث عن آخر شرطة مائلة تفصل المسار عن اسم الملف
		NCPos = InStrRev(SelectedFiles, "\", -1, vbTextCompare)
		' المسار هو كل ما قبل الشرطة
		ThePath = Left(SelectedFiles, NCPos - 1)
		' قد يكون المسار هو الدليل الجذري للقرص. إذن نضيف الشرطة من عندنا
		If Right(ThePath, 1) = ":" Then ThePath = ThePath & "\"
		' اسم الملف هو الواقع بعد الشرطة
		TheFile = Mid(SelectedFiles, NCPos + 1)
		' نضيف اسم الملف و المسار إلى القائمة
		Set AItem = ListView1.ListItems.Add(, , TheFile)
		AItem.SubItems(1) = ThePath
	Else
		' يوجد حرف NULL
		' المسار هو أول جزء في النص قبل أول لحرف NULL
		ThePath = Left(SelectedFiles, NCPos - 1)
		' نحذف جزء المسار ليبقى لدينا أسماء الملفات
		SelectedFiles = Mid(SelectedFiles, NCPos + 1)
		' بنفس الفكرة نستخلص اسم كل ملف إلى أن يبقى لا شيء
		Do While SelectedFiles <> ""
			NCPos = InStr(SelectedFiles, vbNullChar)
			If NCPos = 0 Then
				TheFile = SelectedFiles
				SelectedFiles = ""
			Else
				TheFile = Left(SelectedFiles, NCPos - 1)
			End If
			' نضيف اسم الملف و المسار إلى القائمة
			Set AItem = ListView1.ListItems.Add(, , TheFile)
			AItem.SubItems(1) = ThePath
			SelectedFiles = Mid(SelectedFiles, NCPos + 1)
		Loop
	End If

	Exit Sub
Command1_Click_Error:
	If Err.Number <> cdlCancel Then MsgBox Err.Description, vbCritical, "Error"
End Sub

نرجو الاستفادة و السلام.

الله يعطيك العافية أخي najy_zl زبط معي الله يجازك الخير

بس في مشكلة صغيرة

شوف في الصورة لما احدد أكثر من ملف بحددهم وبضيفهم للـ LisyView

بنضافو من دون أي مشاكل بس لما أحدد الكل يعني لما أحدد كل الملفات بطلع لي رسال خطأ

شوف الصور

---------------------------------

بس لما أحدد الكل بالضغط على Con + A

بيظهر لي مسج وما بضيفهم هل في حل للمشكلة هذه

والله يعطيك الف عافية أخي najy_zl أنتظر حلك أخي najy_zl

الخطأ واضح :)

قم بزيادة الخاصية MaxFileSize فقط والذي يحدد الحد الأقصى لحروف الملفات المحددة

CommonDialog1.MaxFileSize = 32767

شكرا لك أخي DreamNet على التوضيح

الله يعطيك العافية

أخي najy_zl ظهر عندي مشكلة أخرى ولكن ليست من الكود الذي وضعته انت

المشكلة هي انني ما أقدر اضيف مجلدات أو مجلد مع الملفات

هل تقدر تفيدني فيها أخي najy_zl

السلام عليكم...

أصبح الأمر مختلفاً قليلاً لأن الـ Common Dialog لا يسمح باختيار مجلدات، و لذلك فأنت بحاجة لاستدعاء نافذة "اختيار مجلد" الخاصة بـ Windows، و هي تحتاج لاستعمال بعض دوال API. على أية حال أنا شخصياً قمت خلال عملي كمبرمج بتجميع مثل هذه المواضيع (التي أحتاج إليها بين الحين و الآخر) في ملف DLL كتبته بلغة VB نفسها باسم VBAppAss.dll، حتى لا أضطر إلى البحث عنها أو إعادة كتابتها مرات و مرات، و أقوم تلقائياً بتضمين هذا الملف (المكتبة) في أي برنامج أقوم بتصميمه. و قد أرفقت هذا الملف في هذا الرد ليستفيد منه من يشاء.

****** توضيح حول المرفقات ******

تحتوي المرفقات على برنامج setup.exe عند تشغيله يقوم بنسخ الملف VBAppAss.dll إلى المجلد System32 التابع للنظام و يقوم بتسجيله في النظام حتى يكون متوفراً كـ ActiveX component، ثم يقوم اختيارياً بنسخ مجموعة من ملفات المساعدة (ملفات HTML) التي تحتوي على شروح حول الدوال و الإجراءات المتوفرة في المكتبة VBAppAss.dll و كيفية استعمالها.

تنبيه: رغم وجود ملفات المساعدة فإن العديد من الدوال و الإجراءات ما تزال تنقصها الشروحات لأني لم أجد الوقت الكافي لكتابتها، و أرجو أن يتم ذلك في وقت قريب إن شاء الله.

********************************

بعد تركيب المكتبة VBAppAss.dll قم بتشغيل Visual Basic ثم افتح المشروع المطلوب، ثم افتح القائمة Project و اختر الأمر References لتظهر لك نافذة المراجع كما في الصورة:

ابحث في القائمة عن Visual Basic Application Assistant From Daniyah Center و قم بتحديده كما في الصورة، ثم انقر الزر OK.

بعد ذلك و فيما يتعلق بإضافة مجلد استعمل كود كالكود التالي (هذا المثال مطبق على نافذة تحتوي على خانتي لائحة List1 و List2 و زر Command1):

' التصريح على كائن من النوع TFileSystem:
Private MyFileMan As New VBAppAss.TFileSystem

Private Sub Command1_Click()
	Dim Result As String
	' استعمالات TFileSystem:
	' استدعاء نافذة اختيار مجلد التابعة للنظام:
	If MyFileMan.SelectDirectory(Me.hWnd, "الرجاء اختيار المجلد", Result, False)  Then
		' استخلاص اسم المجلد لوحده:
		List1.AddItem MyFileMan.ExtractFileName(Result)
		' استخلاص المسار (المجلد الأب) للمجلد المحدد:
		List2.AddItem MyFileMan.ExtractFilePath(Result)
	End If
End Sub

VBAppAss.rar

نرجو الاستفادة و السلام.

شكراً لك أخي najy_zl على المساعدة

الله يعطيك الف عافية وشكرا لك