ازي اعمل بحث داخل كومبو بوكس

ارجو الرد للاهمية

For w = 0 To List1.ListCount - 1
	If Text1.Text = List1.List(w) Then
		List1.ListIndex = w
	End If
Next w

الكود لايعمل وله علي LIST وله علي Combo

السلام عليكم...

أعتقد أنك لست في حاجة إلى ال TextBox طالما أنه بمكنك ضبط الخاصية Style لل ComboBox على Dropdown Combo و هي القيمة الافتراضية، و بالتالي يمكنك الكتابة فيه مباشرة و إجراء البحث.

على أية حال، الكود التالي يمكنك من إجراء البحث مع الإكمال التلقائي للنص (كالذي نراه عند الكتابة في خانت النص بمتصفح الإنترنت):

' General Declarations section:

'Option Explicit

' Constants for use with SendMessage API function:
Private Const CB_FINDSTRING = &H14C
Private Const CB_ERR = (-1)

' Windows API function used for search:
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long

' User defined function used for search and selecting part of text:
Private Function FindNearestText(AComboBox As Control, KeyAscii As Integer) As Integer
	Dim CB As Long
	Dim FindString As String

	FindNearestText = KeyAscii

	If TypeOf AComboBox Is ComboBox Then	'
		If KeyAscii < 32 Then Exit Function  '  Or KeyAscii > 127
		If AComboBox.SelLength = 0 Then
			FindString = AComboBox.Text & Chr$(KeyAscii)
		Else
			FindString = Left$(AComboBox.Text, AComboBox.SelStart) & Chr$(KeyAscii)
		End If
		CB = SendMessage(AComboBox.hwnd, CB_FINDSTRING, -1, ByVal FindString)
		If CB <> CB_ERR Then
			AComboBox.ListIndex = CB
			AComboBox.SelStart = Len(FindString)
			AComboBox.SelLength = Len(AComboBox.Text) - AComboBox.SelStart
			FindNearestText = 0
		End If
	End If
End Function

' Call the user defined function in the KeyPress event handler of ComboBox:
Private Sub Combo1_KeyPress(KeyAscii As Integer)
	KeyAscii = FindNearestText(Combo1, KeyAscii)
End Sub

قد يمكنك تعديل الكود لإجراء البحث من TextBox بدلاً من ال ComboBox مباشرة

أرجو الاستفادة و السلام