ماهو المكان الصحيح الذي اضع فيه جملة Message Box

مغلق

بدأه mse07 في 16 فبراير 2008 · 2 رد · 860 مشاهدة · في لغة Ms Visual Basic 6 وما قبلها من إصدارات

#116 فبراير 2008 في 11:39 صاحب الموضوع

السلام عليكم ورحمة الله وبركاته

حصلت على كود خاص بمراقبة ملف معين على سبيل المثال :

اذا وجد البرنامج الملف aa.txt على قرص C فانه يظهر Message Box للتذكير بان الملف وصل

Option Explicit
	Dim DATEX$
	  Dim ccc$
	  Dim pID As Long
Private Sub Form_Load()
		Text1.Text = "c:\"
	   Call Timer1_Timer
End Sub
Private Sub mnuFileSub_Click(Index As Integer)
 End
End Sub

Private Sub Timer1_Timer()
	On Error Resume Next
	DATEX$ = "aa"
	DATEX$ = DATEX$ & Right$("0000" + Trim(Year(Date)), 4)
	DATEX$ = DATEX$ & Right$("00" + Trim(Month(Date)), 2)
	DATEX$ = DATEX$ & Right$("00" + Trim(Day(Date)), 2)
	pID = Shell(Environ("Comspec") & " /c DIR " & Trim(Text1.Text) & DATEX$ & "*.* >tmp.tmp")
	Label2.Caption = DATEX$
	Close #1
	Open "tmp.tmp" For Input As #1
mmmm:
	If EOF(1) Then Label1.Caption = " the file not found": Exit Sub
	   Line Input #1, ccc$
	   If InStr(ccc$, DATEX$) > 0 Then Label1.Caption = "the file arrival on c drive": Exit Sub 
GoTo mmmm
End Sub

ماهو المكان الصحيح الذي اضع فيه جملة message box بحيث عندما يكون الملف على قرص C تظهر لي الرساله مره واحده فقط دون تكرار.

ارجو المساعده وشكرا للجميع

#216 فبراير 2008 في 12:08

الأخ الفاضل ...

استخدم الكود التالى

Private sFilepath As String

Private Sub Form_Load()
	sFilepath = "C:\"

	Text1.Text = sFilepath
	Label1.Caption = ""

	Timer1.Interval = 60000 ' Check every 1 minute
	Timer1.Enabled = True
End Sub

Private Sub Timer1_Timer()
	Dim Filename As String

	Filename = sFilepath & "aa" & Format(Date, "yyyymmdd") & ".tmp"

	If Dir(Filename, vbArchive Or vbHidden Or vbNormal Or vbReadOnly Or vbSystem) <> "" Then
		Timer1.Enabled = False
		Label1.Caption = "The file arrival: " & Filename
		MsgBox Label1.Caption
	Else
		Label1.Caption = "File not found: " & Filename
	End If
End Sub

شكراً

Eng. Usama El-Mokadem

Nothing is impossible, the word impossible itself says that: I M - Possible