تعطيل لوحة المفاتيح

اخي بدك تعطل لوحة المفاتيح عن نافزة معينة والا عن الويندوز كله .......

لو أنت عايز تمنع أدخال أى شئ عدا الأرقام فى TextBox مثلا أكتب كودك فى حدث الـ Key_Press بتاع الـ TextBox ده بحيث أنه يرفض المفاتيح عدا الأرقام.

مرحبا شباب ومشكورين على الردود

انا عامل برنامج شبية بشاشة توقف او بمعنى اصح شاشة توقف حيث يظهر تكس بوكس واحد بحيث لايستطيع المستخدم الخروج من البرنامج او استخدام اي زر بلوحة المفاتيح الا بوضع الرقم الصحيح او باعادة تشغيل الجهاز من جديد

اتمنى ان تكون وصلت الفكرة

  Option Explicit
'www.vbforum.com

'In a Module.
Private Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" (ByVal idHook As Long, ByVal lpfn As Long, ByVal hmod As Long, ByVal dwThreadId As Long) As Long

Private Declare Function CallNextHookEx Lib "user32" (ByVal hHook As Long, ByVal nCode As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

Private Declare Function UnhookWindowsHookEx Lib "user32" (ByVal hHook As Long) As Long

Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (pDest As Any, pSource As Any, ByVal cb As Long)

Private Type KBDLLHOOKSTRUCT
	vkCode As Long
	scanCode As Long
	flags As Long
	time As Long
	dwExtraInfo As Long
End Type

Private Const HC_ACTION = 0&
Private Const WH_KEYBOARD_LL = 13&
Private Const VK_LWIN = &H5B&
Private Const VK_RWIN = &H5C&

Private hKeyb As Long

Private Function KeybCallback(ByVal Code As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
	Static udtHook As KBDLLHOOKSTRUCT

	If (Code = HC_ACTION) Then
		'Copy the keyboard data out of the lParam (which is a pointer)
		Call CopyMemory(udtHook, ByVal lParam, Len(udtHook))
		Select Case udtHook.vkCode
			Case VK_LWIN, VK_RWIN
				KeybCallback = 1
				Exit Function
		End Select
	End If
	KeybCallback = CallNextHookEx(hKeyb, Code, wParam, lParam)
End Function

Public Sub HookKeyboard()
	UnhookKeyboard
	hKeyb = SetWindowsHookEx(WH_KEYBOARD_LL, AddressOf KeybCallback, App.hInstance, 0&)
End Sub

Public Sub UnhookKeyboard()
	If hKeyb <> 0 Then
		Call UnhookWindowsHookEx(hKeyb)
		hKeyb = 0
	End If
End Sub

'In the form
Private Sub Form_Load()
HookKeyboard
End Sub

Private Sub Form_Unload(Cancel As Integer)
UnhookKeyboard
End Sub