اخواني لطالما بحثت عن اجابة لهذا السؤال ,ولكن لم اجد ...فهل ساأجد الحل عندكم مشكورين؟

إذا كنت تقصد ان تعطى لخانة النص إسم ملف موجود على الانترنت

فتقوم خانة النص بعرضه كما يعرض فى المتصفح فالاجابه لا أو على الاقل انا لا أعرف طريق تقوم بعمل ذلك إن كانت هناك فعلا هذه الطريقه

أما إن كنت تقصد ان تمرر لخانة النص إسم ملف html لتقوم بعرضه كما يعرض فى المتصفح ؟ فالاجابة هى نفس الاجابه السابقه

أما إن كنت تقصد طريقه تجعلك تقوم بجلب ملف من الانترنت ثم تقوم بعمل تحليل له وتعرض منه النص والصور الموجوده فالاجابه نعم ولا !

نعم للنصوص ولا للصور

أخي الغالي رمضان

اريد باختصار عندي صندوق text

واريد ان اضع محتوى الtext من ملف نصي موجود على الانترنت

على سبيل المثال :

انا عندي مستند نصي مثلا هذا امتدادC:log.txt

طريقة قراته في صندوق text سهله ..

لكن مثلا اذا كان امتداده مثلاhttp://www.arabteam2000.com/log.txt

فكيف يمكنني قراته عبر صندوق text

ومثال على البرنامج اشبه ببرامج جالبة الاخبار التي تقرا من الانترنت

لعلها وضحت الفكرة......

ضع خانة نص بإسم Text1 وأضبط خاصية تعدد الاسطر على ترو وضع زر بإسم command1 وخانتى عنوان بإسم Lable1 and Lable2

ثم ضع الكود الاتى فى قسم الإعلانات

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Copyright ©1996-2002 VBnet, Randy Birch, All Rights Reserved.
' Some pages may also contain other copyrights by the author.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' You are free to use this code within your own applications,
' but you are expressly forbidden from selling or otherwise
' distributing this source code without prior written consent.
' This includes both posting free demo projects made from this
' code as well as reproducing the code in text or html format.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Option Explicit

Private Declare Function URLDownloadToFile Lib "urlmon" _
   Alias "URLDownloadToFileA" _
  (ByVal pCaller As Long, _
   ByVal szURL As String, _
   ByVal szFileName As String, _
   ByVal dwReserved As Long, _
   ByVal lpfnCB As Long) As Long

Private Const ERROR_SUCCESS As Long = 0



Private Sub Form_Load()

   Command1.Caption = "Download File"

End Sub


Private Sub Command1_Click()

   Dim sourceUrl As String
   Dim targetFile As String
   Dim hfile As Long

   sourceUrl = "http://www.mvps.org/vbnet/faq/main/fileloadtext.htm"
   targetFile = "c:deleteme.htm"

   Label1.Caption = sourceUrl
   Label2.Caption = targetFile

   If DownloadFile(sourceUrl, targetFile) Then

      hfile = FreeFile
      Open targetFile For Input As #hfile
         Text1.Text = Input$(LOF(hfile), hfile)
      Close #hfile

   End If

End Sub


Public Function DownloadFile(ByVal sURL As String, _
                             ByVal sLocalFile As String) As Boolean

   Dim lngRetVal As Long

  'if the API returns ERROR_SUCCESS (0), 
  'return True from the function 
   DownloadFile = URLDownloadToFile(0&, _
                                    sURL, _
                                    sLocalFile, _
                                    0&, _
                                    0&) = ERROR_SUCCESS

End Function

مع ملاحظة تغيير المسار الموكود فى الكود إلى موقع الملف الذى ترغب فى عرضه

لست ادري اخي كيف أشكرك

ولكن حسبي ان اقول لك اخي

((جزاك الله الف خير وأدخلك الله فسيح جناته وغفر لك ذنبك,,,,اللهم آمين))))