Record
في بعض المرات تكون الاجابة على سؤال معين نعم او لا امثلة:
هل انت متزوج؟   

هل يجب ان تلبس النظارات اثناء السياقة؟

فلتخزين الجواب تكفي بت واحدة فقط اذا كانت مثلا القيمة لهذه البت 1 تمثل الجواب نعم واذا كانت القيمة صفر فالجواب كلا
واحيانا تكون القيمة المراد تخزينها اقل من بايت (8 بتات) مثلا 
كم عدد الاولاد في الصف ففي بايت واحد يمكن تخزين 255 ولا يمكن ان يكون مثلا في مدرسة ابتدائية او اعدادية او ثانوية عدد طلاب صف بهذا العدد

اذا عندما نريد ان نخزن بيانات معينة ويمكن تخزينها كل واحدة منها بعدد معين من البتات نستعمل ال record 
في لغة الاسمبلي هنالك نوعان من ال record من ناحية الكبر 
1.record بطول 8 بتات (8 bits)

2.record بطول 16 بت (16 bits)
اهمية استخدام ال record

1.توفير ذاكرة

2.تقليل حجم البيانات المخزنة مما يؤدي الى سرعة تحميل (upload) قاعدة البيانات المخزنة فيها هذه البيانات
3.تسريع عمليات البحث والاستفسارات وجلب المعطيات لصغر حجم قاعدة البيانات
المبنى العام لتعريف record
قبل استخدامه لتعريف متغيرات من نوع RECORD يجب تعريف النمط المطلوب
Record_name  record  field1_name:bits_num,field2_nume:bits_num…..
تعريف متغير من نوع record 

Var_name record_name <قيمة الحقل الاول , قيمة الحقل الثاني,….>
مثال:

لدينا مجموعة من الطلاب تتكون من 20 طالبا نريد ان نخزن المعلومات التالية عن كل طالب.
1.كود الطالب (رقم خاص بالطالب) 

2.هل لديه رخصة سياقة ام لا
3.من أي شعبة هو ( تاريخ، فيزيا، كيمياء، حاسوب ، علم اجتماع) أي انه يوجد في المدرسة 5 تخصصات. 
ملاحظة: كل طالب يمكن ان ينتمي الى شعبة واحدة فقط

4. عدد اللغات التي يتقنها من بين هذه اللغات (انجليزية، عربية،فرنسية، اسبانية)
5.عدد الموضيع التي يدرسها اذا علم ان الطالب يدرس من 8 الى 11 موضوعا
تحليل قبل الحل:

لو اردنا استخدام الطريقة السابقة أي بدون استخدام record فنحن بحاجة الى ما يلي:

	المهمة
	عدد البايتات (bytes)

	كود الطالب
	1

	رخصة سياقة
	1

	الشعبة
	1

	عدد اللغات 
	1

	عدد المواضيع
	1


اذا نحن بحاجة هنا الى 5 byte تخزين معلومات عن كل طالب
الحل بمساعدة الطريقة الجديدة:

هنا يجب ان نفكر قبل ان نشتغل:
كود الطالب:

في الفرقة يوجد 20 طالب . يجب ان نعطي لكل طالب رقم خاص ويختلف عن ارقام الطلاب حتى نستطيع ان نميز الطالب. يمكن ان نعمل ما يلي:

الطالب الاول نعطيه الرقم صفر

الطالب الثاني نعطيه الرقم 1

الطالب الثالث نعطيه الرقم 2

اذا الطالب الاخير (الطالب العشرون) نعطيه الرقم 19 السؤال التالي هو كم بتا (bits ) نحن بحاجة لكتابة اكبر كودلدينا وهو الرقم 19 الجواب علينا ان نحول القيمة 19 في الميزان العشري الى الميزان الثنائي

19=(10011)2 
اذا نحن بحاجة الى 5 بتات (bits)

الان بالنسبة لرخصة السياقة تكفي بت واحدة ( صفر تعني لا يوجد لديه رخص 1 تعني نعم يوجد لديه رخصة)

بالنسبة للشعبة نعمل ما يلي:
نرمز لكل شعبة برقم 

	الشعبة
	الرقم

	تاريخ
	0

	فيزياء
	1

	كيمياء
	2

	حاسوب
	3

	علم اجتماع
	4


اذا اكبر قيمة نريد تسجيلها حسب الجدول هي 4 لمعرفة عدد البتات المطلوبة لتسجيل اكبر رقم نحوله الى الميزان الثنائي
4=(100)2 
أي اننا بحاجة هنا الى 3 بتات

عدد اللغات:

يمكن ان لا يتقن هذا الطالب أي لغة . او يمكن ان يتقن لغة واحدة او لغتين او ثلاث لغات او اربع لغات
اذا اكبر عدد هو 4 وكما شاهدنا في الفرع السابق لتسجيل القيمة4 نحن بحاجة الى 3 بتات
بالنسبة لعدد المواضيع التي يدرسها اكبر عدد هو 11 لمعرفة عدد البتات المطلوبة لتسجيل العدد 11 نحوله الى الميزان الثنائي:
11=(1011)2 
اذا نحن بحاجة الى 4 بتات
اذا الحل:

نحن نحاجة الى 5 بتات للكود وبت واحدة لرخصة السياقة و 3 بتات للشعبة و 3 بتات لعدد اللغات التي يتقنها و 4 بتات لعدد المواضيع اذا العدد النهائي هو 16 بتا اذا يمكن استخدام record  من نوع 16 بت أي 2 بايت (byte)
اذا نظرنا الى الجدول السابق والحل النهائي نرى اننا نوفر 3 بايت (byte) لتخزين المعلومات عن كل طالب 
سؤال: هل يجب ان يكون عدد البتات المطلوبة 16 او 8 بالضبط ام ماذا

الجواب: اذا كنا بحاجة الى عدد بتات اصغر من 9 تخزن البيانات على شكل record بطول 8 

اما اذا كنا بحاجة الى عدد بتات اكبر من 8 واصغر من 17 بت تخزن البيانات على record بطول 16 بت

سؤال: من يخبر الاسمبلر بذلك؟
الجواب: يقوم الحاسوب بجمع عدد البتات لكل حقل المسجلة في bits_num لكل حقل ويعرف العدد المطلوب
الان نرجع الى حل السؤال السابق

نعرف نمط جديد من نوع record  بطول 16 بت

اريد ان اعطي كل حقل اسما كما هو مبين في الجدول التالي:

	اسم الحقل
	الرمز
	عدد البتات

	كود الطالب
	Code1
	5

	رخصة
	k
	1

	الشعبة
	D
	3

	اللغات
	L
	3

	المواضيع
	S
	4


اسم النمط الجديد مثلا student_info
Student_info record code1:5,K:1,D:3,L:3,S:3
ننظر الى كيفة التخزين . نحن نعلم اننا بحاجة الى 16 بتا التخزين يتم بالشكل التالي:
	1
	2
	3
	4
	5
	6
	7
	8
	9
	10
	11
	12
	13
	14
	15
	16

	S
	L
	D
	K
	Code1


من الشكل السابق نرى انه لو كنا بحاجة الى 12 بتا فان البرنامج سوف يأخذ record  بطول 16 بتا لان الرقم 12 اكبر من 8  السؤال ماذا مع البتات الاربعة الزيادة 

الجواب: البرنامج يحجزها ويضع فيها القيمة صفر 

السؤال أي اربعة بتات هل من 1-4 او من 13-16 

الجواب: اذا نظرنا الى الجدول السابق نرى انه يبدأ بادخال القيم  من الجهة اليسرى أي انه سوف يحجز 1-4 ويضع بها القيمة صفر
تعريف متغيرات من نوع النمط الجديد 

مثال:

Std1   student_info < , , , , >
هنا تم تعريف متغير باسم std من نوع student_info ولكن بدون ان نعطيه قيم بدائية

Std2 student_info <10,1,2,3,9>
هنا تم تعريف متغير من نوع student_info  مع المعلومات التالية:

	الحقل
	القيمة البدائية
	ملاحظات

	كود
	10
	

	رخصة سياقة
	معه
	لان قيمة الحقل الثاني 1

	التخصص 
	كيمياء
	رقم 2 تعني كيمياء

	عدد اللغات
	3
	

	عدد المواضيع 
	9
	


ملاحظة: يمكن اعطاء جزء من الحقول قيم بدائية ولكن يجب ان يكون عدد الفواصل بين اشارات اكبر واصغر بقدر عدد الحقول ناقص 1 
Std1 student_info <12,0, , , 10>
هنا تم تعريف متغير جديد باسم std1 رقم كوده 12 لا يوجد لديه رخصة سياقة وعدد المواضيع التي يدرسها 10 اما الحقول الاخرى لم نعطيها قيم بدائية. 
يمكن اعطاء القيم او تغيير القيم خلال عمل البرنامج

مثلا يمكن ان نكتب برنامجا يستقبل من كل طالب اسم كود الطالب وهل يوجدلديه رخصة ام لا والشعبة وعدداللغات التي يتقنها وعدد المواضيع التي يتعلمها ونخزنها في الحاسوب.
ويمكن ايضا اجراء عمليات تغيير وبحث وغيرها
طبعا سوف نؤجل هذه العملية حتى نتعلم عن كيفية انشاء ملفات وتخزين البيانات فيها

اوامر ال record

للتعامل مع هذا النمط الجديد نحن بحاجة الى ثلاثة اوامر رئيسية وهي 

الامر الاول: اسم الحقل يرجع عدد الازاحات التي يجب ان عملها حتى يصبح هذا الحقل في الجهة اليمنى 
امثلة:

Mov cx,code1
بعد هذا الامر تصبح قيمة المسجل 
Cx=11
لان الحقل code موجود في البتات من 13-16 وحتى يصبح في البتات من 1-5 يجب ازاحته 11 بتا

Mov bx,L

Bx=4

لان هذا الحقل موجود في البتات من 5-7 وحتى يصبح في البتات من 1-3 يجب ازاحته 4 بتات الى اليمين

بالاختصار عليك عدد عدد البتات التي تقع عن يمينه

Mov cx,K

Cx=10

Mov bx,D

Bx=7 

Mov ax,S

Ax=0

لان هذا الحقل موجود في جهة اليمين

الامر الثاني: mask field_name : يرجع قيمةعددية كلها اصفار ما عدا البتات الموجودة في نفس مكان الحقل المذكور.
Mov ax,mask code
Ax=(1111100000000000)2=F800H
Mov ax, mask K

Ax=(0000010000000000)2=0400H
Mov ax,D
Ax=(0000001110000000)2=0380H
Mov ax, mask L

Ax=(0000000001110000)2=0070H
Mov ax,mask S
Ax=(0000000000001111)2=000FH

الامر الثالث: width field_name يرجع عدد البتات التي يحجزها هذا الحقل امثلة:
Mov ax,width code1
Ax=5

Mov ax, width K

Ax=1

Mov ax,width D
Ax=3
Mov ax,width L
Ax=3
Mov ax,width S
Ax=4
الان  كيف يمكن تعريف 20 طالب؟
الجواب: اذا اردنا ان لا نعطي الطلاب قيم بدائية نسجل ما يلي:

Students student_info 20 dup (< , , , , >)

هنا تم تعريف مصفوفة من نوع student_info بدون ان نعطي الحدود قيم بدائية

اما اذا اردنا نعطي الطلاب قيم بدائية مختلفة نعمل مصفوفة ونعطي 20 قيمة مختلفة لكل طالب قيمة خاصة به .نكتفي في المثال التالي بتعريف مصفوفة تحتوي على ثلاثة طلاب
Students student_info <0,1,2,2,9>, <5,0,1,1,11>,<3,1,3,4,10>
مثال محلول:
لدينا فرقة من الطلاب تتكون من 6 طلاب . في الذاكرة مخزنة معلومات عن كل طالب . كود الطالب  ، نوع الامتحانات (امتحانات شفهية، امتحانات كتابية, امتحان عملي)، عدد الامتحانات على الطالب ان يقدم على الاكثر 3 امتحانات
بما ان عدد الطلاب 6 نعطي كل طالب رقم 

الاول رقم صفر الثاني 1 الثالث 2 

اذا الطالب السادس يأخذ الرقم 5 وهو اكبر قيمة تظهر في الكود 

5=(101)2
اذا نحن بحاجة الى ثلاثة بتات (bits)
نوع الامتحان

نعطي امتحان شفهي الرقم صفر

نعطي امتحان كتابي الرقم 1

نعطي امتحان عملي الرقم 2

اذا اكبر قيمة 2 وهي بحاجة الى 2 بتات لانه

2=(10)2
عدد الامتحانات 

بما ان اكبر عدد امتحانات سيكون 3

اذا نحن بحاجة الى 2 بتات لانه

3=(11)2 

اذا عدد البتات الكلي هو 7 بتات اذا سوف نأخذ record بطول 8 لان العدد الكلي اقل من 9 

اليك الحل التالي:

البرنامج يطلب من المستعمل ادخال كوده في المجال [0..5] ويفحص ما ادخله الطالب اذا كان الكود المدخل خارج المجال يطبع له جملة تخبره انه ادخل كودا خارج المجال ويعطيه فرصة جديدة . اذا ادخل المستعمل كودا ضمن المجال يطبع له البرنامج نوع الامتحان . ويطبع له جملة تطلب منه ادخال رمز Y (حرف كبير) او رمز y (حرف صغير) لانهاء البرنامج والا يعود البرنامج من جديد 
 .model small
.stack 20h
.data
 student_info record code1:3,kind1:2,count1:2
 students student_info <0,1,1>,<1,2,2>,<2,3,0>,<3,2,1>,<4,2,2>,<5,1,2>
 nl db 10,13,'$'
 msg db 10,13,'enter your code in the range [0..5]....$'
 msg2 db 10,13,'to stop the program press y or Y....$'
 msg3 db 10,13,'your code is out of the range, remember [0..5]..$'
 msg4 db 'your kind is....$'
 print macro x
lea dx,x
 mov ah,9
 int 21h
 endm
 .code
   start:mov ax,@data
         mov ds,ax
         print nl
    next:print msg
         mov ah,1
         int 21h
         sub al,30h
         cmp al,5
         jna t1
         print msg3
         jmp next
      t1:mov ah,0
         mov si,ax
         print nl
         print msg4
         mov bl,students[si]
          and bl,mask kind1
          mov cl,kind1
          shr bl,cl
          mov dl,bl
          add dl,30h
          mov ah,2
          int 21h
         print msg2
         mov ah,1
         int 21h
         cmp al,'y'
         jz finish
         cmp al,'Y'
         jz finish
          mov ax,3
          int 10h
         jmp next
   finish:Mov ah,4ch
           Int 21h 
          End start
