Introduction

So, you have a huge amount of data in your MySQL™ database, and your users can move data in and out at will with the VB application that you wrote, but now they want the data in a more meaningful form. In the first Visual Basic application I wrote, I tried to give them summaries and reports by creating forms with dynamically allocated arrays of labels, building the form as I worked my way through the data. 

While such a method worked, and the form looked fairly nice, making changes was difficult. Moving elements around on the form required modification of various constants that were used to control placement and spacing, and changes required a re-compile (granted, I could have loaded the constants from a text file, but I was new). Later, I discovered Crystal Reports®, a powerful tool for report generation. With Crystal Reports, I was able to rebuild my code-based report in a matter of minutes, and modify it at will. When a change was made, I simply had to replace the report file, and Visual Basic would show the new report the next time it was viewed. This really helped me save time on data reporting, and I was able to churn out new reports any time a user would request one.

One of the challenges I had when trying to work with Crystal Reports was getting the report to show in my VB application with data generated using an ADO recordset and MySQL. In fact, with the version of Crystal Reports that comes included with VB6 (version 4.6 of Crystal Reports), this feature was not really supported. I personally prefer to develop software without using a DSN, but in this case I had to make an exception and set up a DSN on my target system so that Crystal Reports could access live data, with the VB application modifying the selection formula of the report in order to allow the user control over what data was displayed in the report. 

Fortunately, when I found myself a developer position in a company that is a reseller for Crystal Reports, and I found myself able to work with Crystal Reports 9. Moving from Crystal Reports 4.6 to Crystal Reports 9 was an improvement similar to moving from hard-coding reports to using Crystal Reports. Version 6 of Crystal Reports introduced Active Data, which allows us to create reports based on ADO provided data. Version 8 of Crystal Reports introduced the Report Designer Component, which greatly improved the way reports are loaded and viewed in VB. In this article I will cover designing and displaying reports using Visual Basic 6, Crystal Reports 9, and MySQL. In a future article I will also cover displaying data with Crystal Reports versions 6 and 4.6.

This article will assume that the reader is using the MySQL RDBMS, but should apply to developers using other database management systems. For an overview of why MySQL is a good choice for Visual Basic developers, see the Why VB/MySQL article on this site. Further information on MySQL, along with full downloads, can be obtained from the MySQL web site. This sample will require the latest version of Connector / ODBC (formerly MyODBC), available for download here (currently 3.51.06). As I stated, this article will be based on Crystal Reports 9 (evaluation copy available for download here). I recommend installing maintenance pack 1 and all monthly hot fixes, available through support.crystaldecisions.com.

On the Visual Basic side, I recommend you have service pack 5 installed for VB, which you can download here. Additionally, the latest version of MDAC (Microsoft Data Access Components) should be installed, and can be found here (currently 2.7 SP1). Finally, this article applies to ADO 2.7 and VB6. It is not applicable to ADO.NET under VB.NET (Unless you reference ADODB in your project and use it for database access).

Creating The Report

Anatomy Of A Report

A crystal report is composed of several sections:

· Report Header 

· Page Header 

· Group Header 

· Detail Line 

· Group Footer 

· Page Footer 

· Report Footer 

Anything placed in the report header and footer will be displayed once in the report. Items in the page header and footer will be displayed on every page. Group headers and footers will be shown once per group of detail lines, and there will be a detail line for every row of data. All sections can be either hidden or suppressed so that they do not appear in the report: hidden sections can be displayed by 'drilling-down' through double clicking on a related section that is displayed, suppressed sections are not displayed at all.

Various information can be placed in any of the report sections including:

· Text Labels 

· Database Fields 

· Images 

· Graphs 

· Summaries 

· Formulas 

Most of these are self-explanatory. Summaries include totals, counts, averages and other aggregate values based on different fields. Formulas allow the report designer to add complex logic and formatting to different fields.

Creating The Field Definitions

Creating a typical report is very simple. First we define the fields that we will be reporting on, then arrange those fields on the form, grouping and summarizing as needed. A field definition file allows us to define the data we will be accessing in our report. Lets start with the table we will be reporting from:

CREATE TABLE report(


transactionid INT UNSIGNED NOT NULL AUTO_INCREMENT PRIMARY KEY,


salesman CHAR(20) NOT NULL,


region CHAR(20) NOT NULL,


amount FLOAT

);

To create a field definition, we bring up the Crystal Reports database expert. The database expert can be accessed by opening a blank report, or by clicking theDatabase Expert menu option under the Database drop-down menu. The available connections treeview will have a Create New Connection branch that when expanded will reveal the Field Definitions Only option. By clicking Create File... button on the file browser dialog, a tool for creating field definition files will be displayed. 

Field definition files are tab separated with .ttx extensions with four values: 

· field name 

· field type 

· field length (if string) 

· sample data 

Field name is taken directly from the name of the field in your recordset (this could be the field name from your underlying table, or the alias you assigned to it using the AS keyword in your query), field type is the datatype of the field, field length specifies the width of a string, and sample data is a static value used to assist in laying out the fields.

A field definition file for the table defined above might look like the following:

transactionid
uLong

1
salesman
String
20
George
region
String
20
Calgary
amount
Currency

30.00


Once we have created our field definition file, we can use it to design our report by dragging it from the 'Available Data Sources' box to the 'Selected Tables' box in the Database Expert and clicking the OK button. Before we go any further, it should be noted that a .ttx file can also be created automatically from a recordset. This can be useful for determining which report datatypes to use, But I find you still need to go in after and give meaningful sample values. Here is a quick sample of how to automatically generate a .ttx file, create a new project with a reference to ADO 2.7 and place the following code in the code section of form1.:

Option Explicit 


'p2smon.dll MUST BE PRESENT IN SYSTEM DIRECTORY 


'IT CAN BE FOUND  IN THE \TOOLS\DEVELOPERS SUBFOLDER 


'OF YOUR CR9 DIRECTORY 

Private Declare Function  CreateFieldDefFile Lib "p2smon.dll" (lpUnk As Object, _ 

ByVal fieldDefFile  As String, ByVal bOverWriteFile As Long) As Long 

Private Sub Form_Load() 


Dim conn  As ADODB.Connection 


Dim rs As ADODB.Recordset 


Dim result As Long 


Set conn = New  ADODB.Connection 


conn.CursorLocation = adUseClient 


conn.ConnectionString = "DRIVER={MySQL  ODBC 3.51 Driver};" _ 



& "SERVER=123.456.789.101;" _  



& "DATABASE=test;" _ 



& "UID=myuser;" _ 



& "PWD=mypass;" _ 



& "OPTION=" & 1 + 2 + 8 + 32 + 2048 + 16384


conn.Open Set rs = New ADODB.Recordset 


rs.Open "SELECT * FROM report", conn, adOpenStatic,  adLockReadOnly 


'PASS RECORDSET, PATH TO GENERATED FILE, TRUE/FALSE TO OVERWRITE  


result = CreateFieldDefFile(rs, App.Path & "\report.ttx", True)  


If result Then 



MsgBox "File " & App.Path & "\report.ttx created  successfully", vbInformation, "Success!" 


Else 



MsgBox "Failed  to create ttx file!", vbCritical 


End If 

End Sub  

Placing Fields, Grouping, and Summarizing

By choosing the Field Explorer under the View menu, we can use the field explorer to choose fields and place them onto the form. After dragging each of the fields onto the form, we can group data to make it more meaningful.

Under the Report menu, the Group Expert option will bring up the Grouping Expert. With the grouping expert we can choose which fields we will be grouping by (in our case region, then salesman).

Once grouping is specified, we will see the two groups added to our report, with the group names now shown as part of the main report in the group header sections. By right-clicking on these two section headers, we can choose the suppress option to prevent these group headers from being displayed.

To summarize data, we click on the field we wish to summarize, and choose Summary from the Insert menu. The Insert Summary dialog gives us options to choose which field to summarize (in our case the amount field), what summary to perform (we will calculate the Sum), and where the resulting value is to be placed (will will place one in the footer for each group and in the report footer). The summaries are then available on the report for us to format and place.

Adding Formulas

Once our data is placed on the report, we can create calculated fields by creating formulas. Formulas can be written in either the Crystal Reports syntax, or in CR9, we can use Visual Basic syntax. Lets add a simple formula to display commission for our sales; in the field explorer, right click on the Formula Fields header and choose New, this will display the formula editor after prompting you for a formula name (commission will suffice for a name). In the top right you will find a drop-down box displaying Crystal Syntax, change it to say Basic Syntax so we can work with Visual Basic type syntax. Next, in the formula window type the following:

formula = {article.amount} * 0.05

Now you can click save and close the formula window. The new formula is now available in the field browser and can be placed on the report in the detail section. We can add summaries of the formula if we wish.

Well, that gives us a basic report, you can press the F5 key to see a preview of the report using the sample data you entered in your .ttx file. You next step will be to show the report to your users in your VB application using data retrieved from MySQL.

Displaying The Data

With Crystal Reports 8 and higher, the OCX Crystal Viewer is done away with to be replaced with the Report Designer Component. This approach allows for a more object-oriented approach to displaying reports. One benefit is that the report viewer is not placed directly on the form, allowing for the report to appear in a specific region of the form without spawning a separate form.

The process for displaying the report in VB is fairly simple: 

· instantiate ADODB Connection and Recordset objects 

· populate recordset object with query 

· instantiate Crystal Reports Application and Report objects 

· open report 

· bind report to recordset 

· bind report to viewer 

· show report 

To display a report in your Vb application you will need the following:

References:

· Microsoft ActiveX Data Objects 2.7 Library 

· Crystal Reports 9 ActiveX Designer Run Time Library 

Components:

· Crystal Reports Viewer Control 9 

You will also need a Crystal Reports Viewer Control placed on your form named CRViewer.

Preparing Data

First we are going to need the data that we will be reporting on. This is done using ADO:

Dim conn As ADODB.Connection

Dim rs As ADODB.Recordset

Set conn = New ADODB.Connection

conn.CursorLocation = adUseClient 'SERVER-SIDE NOT RECCOMENDED

conn.ConnectionString = "DRIVER={MySQL ODBC 3.51 Driver};" _ 

   & "SERVER=127.0.0.1;" _

   & "DATABASE=crystal;" _

   & "UID=root;" _

   & "PWD=coco;" _

   & "OPTION=" & 1 + 2 + 8 + 32 + 2048 + 163841 'SET ALL PARAMETERS

conn.Open 'THESE OPTION VALUES ARE BEST FOR VB

conn.Execute "DROP TABLE IF EXISTS report", , adExecuteNoRecords

   'ADEXECUTENORECORDS IS USED FOR

   'QUERIES THAT RETURN NO DATA

   '(CREATE, INSERT, DELETE, ETC.)

conn.Execute "CREATE TABLE report(" _

   & "transactionid INT UNSIGNED NOT NULL AUTO_INCREMENT PRIMARY KEY,"    _

   & "salesman CHAR(20) NOT NULL," _

   & "region CHAR(20) NOT NULL," _

   & "amount Float)", , adExecuteNoRecords 
'THE TABLE WE WILL REPORT OFF OF








'PUT SOME DATA IN THE TABLE

conn.Execute "INSERT INTO report(salesman, region, amount) VALUES('George','Calgary',30.00)",    , adExecuteNoRecords

conn.Execute "INSERT INTO report(salesman, region, amount) VALUES('George','Calgary',15.00)",    , adExecuteNoRecords

conn.Execute "INSERT INTO report(salesman, region, amount) VALUES('George','San    Jose',10.00)", , adExecuteNoRecords

conn.Execute "INSERT INTO report(salesman, region, amount) VALUES('Jerry','Calgary',30.00)",    , adExecuteNoRecords

conn.Execute "INSERT INTO report(salesman, region, amount) VALUES('Jerry','San    Jose',100.00)", , adExecuteNoRecords

Set rs = New ADODB.Recordset

rs.Open "SELECT * FROM report", conn, adOpenStatic, adLockReadOnly

Preparing and Displaying the Report

Now that we have a recordset, we just need to load the report, link it to the recordset and the viewer, and display it:

Dim crystal As CRAXDRT.Application 'LOADS REPORT FROM FILE

Dim report As CRAXDRT.report 

'HOLDS REPORT

CRViewer.DisplayBorder = False 
'MAKES REPORT FILL ENTIRE FORM

CRViewer.DisplayTabs = False 

'THIS REPORT DOES NOT DRILL DOWN, NOT NEEDED

CRViewer.EnableDrillDown = False 
'REPORT DOES NOT SUPPORT DRILL-DOWN

CRViewer.EnableRefreshButton = False 
'ADO RECORDSET WILL NOT CHANGE, NOT NEEDED

Set crystal = New CRAXDRT.Application 

'MANAGES REPORTS

Set report = crystal.OpenReport(App.Path & "\report1.rpt") 
'OPEN OUR REPORT

report.DiscardSavedData 


'CLEARS REPORT SO WE WORK FROM RECORDSET

report.Database.SetDataSource rs 
'LINK REPORT TO RECORDSET

CRViewer.ReportSource = report 
'LINK VIEWER TO REPORT

CRViewer.ViewReport 



'SHOW REPORT

Do While CRViewer.IsBusy 


'ZOOM METHOD DOES NOT WORK WHILE

   DoEvents 





'REPORT IS LOADING, SO WE MUST PAUSE

Loop 







'WHILE REPORT LOADS.

CRViewer.Zoom 94

Once the report is displayed, we can then cleanup out objects:

rs.Close 'ALL BELOW HERE IS CLEANUP

Set rs = Nothing

conn.Close

Set conn = Nothing

Set crystal = Nothing

Set report = Nothing

Finally, we can add some code to the Form_Resize event to ensure that our report occupies the entire form:

Private Sub Form_Resize() 'MAKE SURE REPORT FILLS FORM

   CRViewer.Top = 0 'WHEN FORM IS RESIZED

   CRViewer.Left = 0

   CRViewer.Height = ScaleHeight

   CRViewer.Width = ScaleWidth

End Sub

Conclusion

And there you have it. If all goes well, you now have a report displaying on your VB form, generated from MySQL data. From here you can look at creating more complex formulas, pulling data from multiple recordsets, and reporting on queries more complex than your typical SELECT * query.

