
سنبدأ على بركة الله بشرح طريقة نقل الملفات عن طريق أداة الـ Winsock ، من الخادم إلى العميل، و تشغيلها إذا كان امتداد الملف exe
إن هذا النوع من نقل البيانات يعد من أعقد العمليات التي يقوم بها برنامج خادم-عميل ، لذلك سأحاول شرحها نظريا، ثم عمليا، و بطريقة مبسطة و سهلة للفهم...

أولا سأشرح لكم الخطوات التي نتبعها لإرسال أي ملف من العميل إلى الخادم.
إن نقل ملف صغير الحجم (أي بين 1 إلى 100 بايت) عملية سهلة جدا، و لكن ماذا لو كان الملف حجمه أكبر من 500 كيلو بايت، هنا المشكلة، و خاصة أن كمية البيانات التي تنقلها أداة الـ Winsock محدودة.
إذا ما الحل هنا... يجب علينا في هذه الحالة تقسيم الملف إلى عدة أجزاء و نقل كل جزء على حدة، و عندما يستقبل الخادم هذه الأجزاء يجمعها في ملف واحد لنحصل على الملف ذاته الذي نقله العميل.

** كيف يمكننا تقسيم الملف:
في هذه الفقرة يجب تعلم كيفية تقسيم الملف إلى أجزاء عدة بحيث يستطيع الوينسوك نقلها. أي يجب فتح الملف المعني بصيغة Binary (بصيغة ثنائية) و تجزيئه ثم نقل كل جزء على حدة.
سأقوم بشرح كل ما يخص فتح الملف بصيغة Binary لكي يصبح لنا حرية التعامل مع الملفات.
إن فتح الملفات بصيغة Binary هي عملية فتح مثلها مثل فتح الملفات بصيغة عشوائية أو تسلسلية. و تتم عملية الفتح بصيغة Binary على الشكل التالي:

كود:

Dim F

F = FileNum

Open "FileDir" For Binary As F


هنا قمنا بتعريف متغير F و وضعنا فيه قيمة معينة موجودة في التابع FileNum حيث يحمل هذا التابع قيمة معينة لتعريف الملف المعني بها... أي عمليات القراءة و الكتابة من و إلى الملف تتم عن طريق هذا التابع، و الذي وضعنا قيمته في F
ثم قمنا بفتح الملف بصيغة Binary . طبعا الــ "FileDir" هي مسار الملف الذي نريد فتحه موضوعا بين علامات اقتباس.
هنا قمنا بفتح الملف، و لكن لم نقم بعمل أي عملية له، أي أننا لم نقرأ أو نكتب فيه أي شيء...
إن القراءة من الملف تتم بعدة طرق، أشهرها تحديد عدد المحارف أو البايتات التي نريد قرائتها، أو قراءة الملف كاملا.
و تكون قراءة عدد معين من المحارف أو البايتات على الشكل التالي:

كود:

Dim S

S = Space(100)

Get #F, , S


عرفنا في هذا الكود متغير S ليحمل قيمة المحارف أو البايتات المقروءة من الملف، و من ثم حددنا أننا نريد قراءة 100 بايت من الملف من خلال السطر الثاني، و في السطر الأخير قمنا بوضع البايتات الـ 100 في المتغير S
الآن إذا قمنا بكتابة السطر الثالث مرة أخرى، فإنه سيقرأ البايتات الـ 100 التي تلي المئة السابقة...
و أيضا يجدر بي أن أنوه أن سطر قراءة البيانات Get يحوي ثلاث خانات، و هي:
1) أو خانة وضعنا فيها المتغير F و الذي يحمل قيمة تعريف الملف.
2) ثاني خانة نحدد فيها البايت الذي نريد بدء القراءة عنده.
3) الخانة الثالثة و الأخيرة نضع فيها المتغير الذي سيحمل البايتات المقروءة.

ملاحظة: لقد تركت الخانة الثانية فارغة في الكود السابق لكي يبدأ القراءة من البداية، و إذا وضعنا السطر Get مرة أخرة فيبدأ من البايت 101، و من ثم من البايت 201 و هكذا...
أما إذا أردنا قراءة 100 بايت، و الملف لا يحوي 100، فسيعطينا رسالة خطأ...
لذلك يجب علينا معرفة كيف يمكن حساب عدد بايتات الملف، و هي عن طريق تابع معين و هو:

كود:

A = Lof(F)


حيث أن الــ Lof تعطينا عدد بايتات الملف الذي رقمه F

الآن علينا تعلم كيفية الكتابة لملف بصيغة Binary و هي عملية تشبه عملية القراءة كثيرا. 
إن كود الكتابة هو:

كود:

Put #F, 1, Data


و نلاحظ أن الأمر Put أيضا له ثلاث خانات بعده، و هي:
1) أول خانة لنضع الرقم الذي يعبر عن الملف F
2) الخانة الثانية لتحديد مكان بدء الكتابة.
3) الخانة الثالثة لتحديد البيانات التي نريد كتابتها.

أظن أننا الآن تعلمنا كفاية معظم خصائص فتح و قراءة الملف بصيغة Binary و بقي علينا تطبيق ما تعلمناه.
برمجت لكم برنامج بسيط جدا لإرسال ملفات من النوع exe فقط، و هو موجود في الملفات المرفقة. و سأتطرق لشرح الأكواد الموجودة فيه.

أولا البرنامج مؤلف من خادم و عميل، حيث يقوم العميل بالإتصال بالخادم، و ينشأ اتصال بينهما. و من العميل نختار الملف الذي نريد إرساله ثم نضغط زر إرسال. هذه هي فكرة البرنامج كاملة.
إن أكواد الإتصال و قبول الإتصال تطرقنا لها في الدروس الأولى، لذا سأشرح هنا فقط الأكواد التي تخص موضوعنا...
عند الضغط على الزر إرسال، يتنفذ معنا الكود التالي:

كود:

Private Sub cmdSend_Click()

Dim F

Dim I

Dim S As String

' إذا كان لا يوجد اتصال
If Winsock1.State <> 7 Then

MsgBox "إنت غير متصل مع الخادم"

Exit Sub

End If

' تجزيء الملف و نقل كل جزء على حدة
F = FreeFile

lblStatus.Caption = "جاري تحميل الملف"

Sendcomplete = False

Open txtDir.Text For Binary As F

For I = 1 To LOF(F) \ 1024

S = Space(1024)

Get #F, , S

Winsock1.SendData S

FileLate

Next I

If LOF(F) Mod 1024 Then

S = Space(LOF(F) Mod 1024)

Get #F, (LOF(F) - (LOF(F) Mod 1024)) + 1, S

Winsock1.SendData S

FileLate

End If

Close F

Winsock1.SendData "EndDownload"

lblStatus.Caption = "لقد تم تحميل الملف بنجاح"

End Sub


في أول الكود نعرف ثلاث متغيرات، الأول F ليحمل رقم الملف، و الثاني I سنستخدمه كعداد، و الثالث S لنضع فيه القيم المقروءة من الملف.
و من ثم نقوم باختبار حالة الإتصال للأداة Winsock فإذا كان الإتصال غير قائم نقوم بإظهار رسالة بهذا الأمر ثم ننهي الإجراء..
بعد ذلك قمنا بتحديد رقم الملف، و قمنا بفتحه بصيغة Binary من خلال القسم التالي:

كود:

F = FreeFile

lblStatus.Caption = "جاري تحميل الملف"

Sendcomplete = False

Open txtDir.Text For Binary As F


الآن بقي علينا عملية إرسال الملف. سأشرح أولا كيف قمت بكتابة الكود نظريا و من ثم أقوم بشرح الكود الخاص بذلك.

كود:

For I = 1 To LOF(F) \ 1024

S = Space(1024)

Get #F, , S

Winsock1.SendData S

FileLate

Next I

If LOF(F) Mod 1024 Then

S = Space(LOF(F) Mod 1024)

Get #F, (LOF(F) - (LOF(F) Mod 1024)) + 1, S

Winsock1.SendData S

FileLate

End If

Close F


لقد اخترت أن أجزء الملف إلى أجزاء كل منها يساوي 1024، أي كيلو بايت واحد، و من ثم إرسال كل جزء على حدة. و لكن بعض الملفات من الممكن أن تحتوي على مثلا 20 كيلو بايت، و 31 بايت، لذا نرسل أول عشرين كيلو و من ثم نرسل الجزء الأخير المكون من 31 بايت.
سأتطرق قليلا لموضوع خارجي عن عملية القسمة لفهم أكثر للعملية.

كود:

25 \ 3   'هذه العملية تعطينا الناتج  بدون باقي (يعني 8)

25 / 3   'هذه العملية تعطينا الناتج كاملا ( يعني  8.3333333333)

25 Mod 3   'هذه العملية تعطينا الباقي من العملية (و هو 1)


الآن راقبو السطر الأول من كود إرسال الملف:

كود:

For I = 1 To LOF(F) \ 1024


كونا من خلال هذا السطر حلقة تبدأ من 1 إلى عدد الكيلو بايتات في الملف ما عدا الباقي، يعني إذا كان الملف حجمه 4 كيلوبايت و 42 بايت، فإن الحلقة تكون من 1 إلى 4

في الأسطر التالي:

كود:

S = Space(1024)

Get #F, , S

Winsock1.SendData S

FileLate


نقوم بقراءة أول 1024 بايت من الملف و نرسله عبر أداة الوينسوك، و من ثم يتم تنفيذ إجراء Filelate ( سأكتب كود هذا الأجراء لاحقا)
ما هو عمل هذا الإجراء Filelate، إن عمله هو تأخير إرسال الجزء التالي حتى يرسل الجزء الأول كاملا. لأنه على سبيل المثال إذا كتبنا الكود التالي:

كود:

Winsock1.SendData "A"

Winsock1.SendData "B"


فإنه يصل للطرف الآخر على الشكل "AB"، لذلك قمنا بوضع الإجراء Filelate لينتظر حتى يتم إرسال الجزء الأول، و من ثم يقوم بإكمال الحلقة و إرسال الجزء التالي. و هكذا حتى يتم إرسال كامل الأجزاء.
و لكن بقي لدينا الآن الجزء الأخير، و هو الباقي من البايتات، و الذي يجب أن نرسله أيضا و إلا فإن الملف سيكون ناقصا في الطرف الآخر.
لذا كتبنا الكود التالي بعد حلقة الإرسال:

كود:

If LOF(F) Mod 1024 Then

S = Space(LOF(F) Mod 1024)

Get #F, (LOF(F) - (LOF(F) Mod 1024)) + 1, S

Winsock1.SendData S

FileLate

End If


وضعنا في هذا الكود جملة شرطية بحيث إذا كان هناك باقي من البايتات ينفذ عمل الإرسال للمتبقي. فكما ذكرت لكم مسبقا فإن LOF(F) Mod 1024 يعطينا الباقي من البايتات. فنقوم بتفريغ مساحة في المتغير S بعدد البايتات المتبقية، و نقوم بقراءتها من الملف، حيث نحدد بداية القراءة من (LOF(F) - (LOF(F) Mod 1024)) + 1 أي من أول بايت من الباقي بطول عدد البايتات المتبقية. و نرسل هذه البايتات.

إن الإجراء Filelate يعد من أهم إجراءات كود إرسال الملفات، لأن بدونه يكون كل الكود خطأ بخطأ... 
أولا نعرف متغير من النوع Boolean في قسم التصريحات العام، حيث سيحمل هذا المتغير قيمة True إذا تم إكمال إرسال جزء معين، و False عند بدء إرسال أي جزء...
يعني، في الحدث SendComplete للأداة ًWinsock نضع الكود التالي:

كود:

Private Sub Winsock1_SendComplete()

Sendcomplete = True

End Sub


حيث يتم هذا الحدث عند يتم إنهاء إرسال شيء معين للأداة.
و كما لاحظتم إننا وضعنا الكود التالي ضمن إجراء إرسال الملف:

كود:

SendComplete = False


و على أساس هذا المتغير، نكتب الإجراء FileLate على الشكل التالي:

كود:

' إجراء لتأخير وقت إرسال أي جزء من الملف
'إلى أن يرسل الجزء الذي قبله تماما
Public Sub FileLate()

On Error Resume Next

Sendcomplete = False

Do Until Sendcomplete

DoEvents

Loop

End Sub


علينا كتابة هذا الإجراء ضمن كود العميل، حيث أنه يقوم بعمل حلقة فارغة (فقط لتضييع الوقت) طوال فترة قيمة SendComplete = False، إي طوال فترة إرسال جزء معين، و يتم إنهاء هذه الحلقة عندما تصبح قيمة المتغير True، ليعود التنفيذ إلى حلقة إرسال الأجزاء و تكمل عملها... و هكذا ...

و أخيرا، في آخر كود الإرسال نلاحظ السطر التالي:

كود:

Winsock1.SendData "EndDownload"


و الذي يقوم بإرسال عبارة معينة للخادم يخبره بها بأنه انتهى من إرسال الملف.
و بهذا انتهينا من شرح إرسال الملف من العميل.
ننتقل إلى شرح كود الخادم في استقبال الملف، و هو كود أسهل بكثير من كود الإرسال...

في الحدث DataArrival للأداة وينسوك في برنامج الخادم، كتبنا الكود التالي:

كود:

Private Sub Winsock1_DataArrival(ByVal bytesTotal As Long)

Dim Data As String

Dim F

Winsock1.GetData Data

If Data = "EndDownload" Then

lblStatus.Caption = "لقد تم التحميل بنجاح"

Exit Sub

End If

F = FreeFile

Open "C:\Windows\Desktop\File.exe" For Binary As F

Put #F, LOF(F) + 1, Data

lblStatus.Caption = "جاري استقبال الملف"

Close F

End Sub


في اول الكود نعرف متغيرات، الأول Data لوضع البيانات المستقبله فيه، و الثاني F ليحميل رقم الملف الذي نريد إنشاءه.
ثم نقوم باستقبال البيانات من العميل.
الآن، وضعنا أداة شرطية في حال كانت البيانات المستقبلة هي EndDownload حينها نقوم بعمل أي عمل نريده... في الكود الذي كتبته قمت بإظهار رسالة للمستخدم بان استقبال الملف قد اكتمل.
و لا ننسى الأمر Exit Sub لكي ينهي الإجراء و إلا بدونه سيقوم البرنامج بإضافة عبارة Download للملف، مما يؤدي إلى عطب في الملف.

في الأسطر التالية، قمنا بتحديد رقم للملف، و فتحنا ملف في المسار التالي:

"C:\Windows\Desktop\File.exe"

طبعا إن فتح ملف غير موجود يقوم بإنشاءه، يعني الملف File.exe غير موجود بالأصل، لذا يقوم هذا الكود بإنشاءه و لكنه لا يحتوى إلا على 0 بايت.
ثم يقوم بوضع البيانات المستقبلة فيه من خلال الأمر Put ابتداءا من نهايته.
يعني عند استقبال الخادم لأول جزء فإنه يبدأ بوضع البيانات ابتداءا بالبايت 1 ، و عند استقبال الجزء الثاني يضع البيانات ابتداءا بالبايت 1025، و هكذا إلى أن يتم استقبال كامل البايتات و ترتيبها بشكل متتالي و يكون الملف قد اكتمل تماما...
لقد قمت و الحمدلله بإكمال شرح كامل المثال الذي أرفقته لكم مع الملفات المرفقة، و لكنه غير كامل، و بسيط جدا، و فيه نقاط ضعف، و هي إذا أرسلت ملف آخر فإنه سيضع مع الملف الأول، مما يؤدي إلى إنشاء ملف ليس له أي عمل... لذا أريد منكم إن تقوموا أنتم بتطويره من خلال الخطوات التالي:

1) وضع شريط تمرير يبين سير عملية التحميل. 

2) القدرة على تحميل جميع أنواع الملفات، بحيث يحفظ الخادم الملف الذي سيستقبله بنفس إسم الملف الذي أرسله العميل.
تنويه: يكون هذا الأمر بأن نرسل في البداية اسم الملف من العميل إلى الخادم.

3) وضع زر لإيقاف التحميل من قبل المستخدم.

4) التحسس لعملية قطع الإتصال خلال عملية الإرسال، أي أن يقوم العميل بإظهار رسالة للمستخدم بأن الإتصال قد انقطع أثناء عملية التحميل (طبعا في حال انقطع الإتصال لسبب ما )

