[تمت الاجابه] طريقة تشفير الحروف المدخلة في inputbox

[hct111 0]

السلام عليكم ورحمة الله وبركاته

اذا سمحتو اعضاء المنتدى

محتاجة طريقة لتحويل الحروف في input box لما اليوزر يدخلها الى نجوم

يعني مثل الباسوورد

وشكرا لكم

[ksmn64 16]

أختي الكريمة

الأمر سهل جداً حددي الحقل المطلوب وفي خصائص الحقل في تبويب البيانات إختاري (قناع الإدخال) وإختاري من القائمة كلمة المرور فيصبح الحقل يظهر على شكل نجوم .

إذا لم تصل الفكرة أرفقي مثال ليتم التعديل عليه .

[alcasir 5]

اخي انا استخدم هذا الكود عند فتح نموذج برقم سري...

ارغب الرقم السري يظهر على شكل نجوم عند محاولة كتابته

a = InputBox("ادخل كلمة المرور")

If a <> 1234 Then

Cancel = True

End If

ما هو التعديل المطلوب في الكود

مع الشكر الجزيل

تم تعديل 1 Mar 2011 بواسطه alcasir

[malik2010 99]

تفضل

هذا الكود يوضع في وحدة نمطية وهو خاص لتحويل الارقام الى نجوم في مربع ال inbox

Option Compare Database
Option Explicit

'API functions to be used
Private Declare Function CallNextHookEx Lib "user32" (ByVal hHook As Long, _
                                                      ByVal ncode As Long, ByVal wParam As Long, lParam As Any) As Long

Private Declare Function GetModuleHandle Lib "kernel32" Alias "GetModuleHandleA" (ByVal lpModuleName As String) As Long

Private Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" _
                                          (ByVal idHook As Long, ByVal lpfn As Long, ByVal hmod As Long, _
                                          ByVal dwThreadId As Long) As Long

Private Declare Function UnhookWindowsHookEx Lib "user32" (ByVal hHook As Long) As Long

Private Declare Function SendDlgItemMessage Lib "user32" Alias "SendDlgItemMessageA" _
                                            (ByVal hDlg As Long, ByVal nIDDlgItem As Long, ByVal wMsg As Long, _
                                            ByVal wParam As Long, ByVal lParam As Long) As Long

Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hwnd As Long, _
                                                                          ByVal lpClassName As String, _
                                                                          ByVal nMaxCount As Long) As Long

Private Declare Function GetCurrentThreadId Lib "kernel32" () As Long

'Constants to be used in our API functions
Private Const EM_SETPASSWORDCHAR = &HCC
Private Const WH_CBT = 5
Private Const HCBT_ACTIVATE = 5
Private Const HC_ACTION = 0

Private hHook As Long

Public Function NewProc(ByVal lngCode As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
    Dim RetVal
    Dim strClassName As String, lngBuffer As Long

    If lngCode < HC_ACTION Then
        NewProc = CallNextHookEx(hHook, lngCode, wParam, lParam)
        Exit Function
    End If

    strClassName = String$(256, " ")
    lngBuffer = 255

    If lngCode = HCBT_ACTIVATE Then    'A window has been activated

        RetVal = GetClassName(wParam, strClassName, lngBuffer)

        If Left$(strClassName, RetVal) = "#32770" Then  'Class name of the Inputbox

            'This changes the edit control so that it display the password character *.
            'You can change the Asc("*") as you please.
            SendDlgItemMessage wParam, &H1324, EM_SETPASSWORDCHAR, Asc("*"), &H0
        End If

    End If

    'This line will ensure that any other hooks that may be in place are
    'called correctly.
    CallNextHookEx hHook, lngCode, wParam, lParam

End Function

Public Function InputBoxDK(Prompt, Optional Title, Optional Default, Optional XPos, _
                        Optional YPos, Optional HelpFile, Optional Context) As String

    Dim lngModHwnd As Long, lngThreadID As Long

    lngThreadID = GetCurrentThreadId
    lngModHwnd = GetModuleHandle(vbNullString)

    hHook = SetWindowsHookEx(WH_CBT, AddressOf NewProc, lngModHwnd, lngThreadID)

    InputBoxDK = InputBox(Prompt, Title, Default, XPos, YPos, HelpFile, Context)
    UnhookWindowsHookEx hHook

End Function

تفضل هذا رابط يشرح الطريقة

http://www.arabteam2000-forum.com/index.php?showtopic=96686

بالتوفيق

تم تعديل 1 Mar 2011 بواسطه malik2010

[hct111 0]

شكرا جميعا على الردود

ولكن لما اتوص للحل بعد

اخي ksmn

طريقتك تخدمني اذا كنت اريد انفذ المطلوب في الحقل

ولكن انا اريد انفذه في inputbox مثل ما طلب الاخ alcasir

في انتظار المزيد من الردود

وشكرا على المحاولات

[malik2010 99]

الاخت hct111

لاحظي المشاركة رقم 4

والرابط اسفله يشرح طريقة عملها

تحياتي

[hct111 0]

شكرا جزيلا الك ملك

جربتها الطريقة بس ما ضبطت

بس بعد بحاول وان شاء الله بتضبط

واذا في اي طرق ثانيه انا في الانتظار

[hct111 0]

اعضاء المنتدى الله يخليكم انا في امس الحاجه لحل هذه المشكلة

في انتظار الطرق والحلول

[roan27 89]

شاهدي المرفق

input.rar

[الـحياري 0]

تفضلي اختي الكريمة

Microsoft Access.rar

[Mahmoud Mahmad Sidiek 0]

اذا كان ما تريدنه مثل ما انا فهمت

فيمكنك ذلك من

field properties - input mask - password

[hct111 0]

الف مليون شكر الكم جميعا

حملت الامثلة وطبقت على مثالي وضبط

الله يحفظكم ويبارك لكم في اولادكم واموالكم واهاليكم ويزيدكم علم